SCons renaming updates for base, net and googleurl:

* Rename SConscript files to {module}.scons or {moduel}_lib.scons,
  depending on the primary target involved.
* Separate targets into individual *.scons files, with one
  construction environment (named "env") per *.scons file.
* Add using_{module}.scons files (like .vsprops) that will be used
  by other modules to add CPPDEFINES, CPPPATH, LIBS and LIBPATH values.
* Update other modules' *.scons files to use the new using_{module}.scons
  files (using a temporary one-liner idiom until we have the
  ApplySConscript() method from the Hammer modules).
* Use the idiom of removing to-be-ported files from the master list,
  so they can be simply deleted from the to-be-ported list as they
  get ported in the future, instead of having to shuffle entries
  between lists.
* Use $OBJ_ROOT instead of hard-coded '#/$BUILD_TYPE/' for the $*_DIR
  variables.
* Add a addRepository() call mapping build/ to $TARGET_ROOT/googleurl,
  so its $OBJ_ROOT value can look like the others'.
* Formatting changes, primarily modifying indentation to conform to
  style guidelines.
* Fix copyright headers in some third_party/* modules
  previously overlooked.
* Add rudimentary __doc__ strings, setting up for a future
  ability to generate meaningful documentation.


Review URL: http://codereview.chromium.org/7807

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@3675 0039d316-1c4b-4281-b951-d872f2087c98

1 files changed, 79 insertions, 0 deletions

diff --git a/base/gfx/base_gfx.scons b/base/gfx/base_gfx.scons
new file mode 100644
index 0000000..9a5e992
--- /dev/null
+++ b/base/gfx/base_gfx.scons
@@ -0,0 +1,79 @@
+# Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+__doc__ = """
+Configuration for building base_gfx.lib / libbase_gfx.a.
+"""
+
+Import('env')
+
+env = env.Clone()
+
+env.SConscript([
+    '$ICU38_DIR/using_icu38.scons',
+    '$LIBPNG_DIR/using_libpng.scons',
+    '$SKIA_DIR/using_skia.scons',
+    '$ZLIB_DIR/using_zlib.scons',
+], {'env':env})
+
+env.Prepend(
+    CPPPATH = [
+        '$ROOT_DIR',
+    ],
+)
+
+if env['PLATFORM'] == 'win32':
+  env.Prepend(
+      CCFLAGS = [
+          '/TP',
+          '/WX',
+      ],
+  )
+
+input_files = [
+    'convolver.cc',
+    'font_utils.cc',
+    'gdi_util.cc',
+    'image_operations.cc',
+    'native_theme.cc',
+    'png_decoder.cc',
+    'png_encoder.cc',
+    'point.cc',
+    'rect.cc',
+    'size.cc',
+    'skia_utils.cc',
+    'uniscribe.cc',
+    'vector_canvas.cc',
+    'vector_device.cc',
+]
+
+if env['PLATFORM'] in ('posix', 'darwin'):
+  # Remove files that still need to be ported from the input_files list.
+  # TODO(port): delete files from this list as they get ported.
+  to_be_ported_files = [
+      'font_utils.cc',
+      'gdi_util.cc',
+      'native_theme.cc',
+      'skia_utils.cc',
+      'uniscribe.cc',
+      'vector_canvas.cc',
+      'vector_device.cc',
+  ]
+  for remove in to_be_ported_files:
+    input_files.remove(remove)
+
+if env['PLATFORM'] == 'win32':
+  input_files.extend([
+      'bitmap_platform_device_win.cc',
+      'platform_canvas_win.cc',
+      'platform_device_win.cc',
+  ])
+elif env['PLATFORM'] == 'posix':
+  input_files.extend([
+      'bitmap_platform_device_linux.cc',
+      'platform_canvas_linux.cc',
+      'platform_device_linux.cc',
+  ])
+
+env.ChromeStaticLibrary('base_gfx', input_files)