Move nsimage_cache into base so that it can be accessed from outside of chrome.

This is in support of the next round of rebundling.

TEST=does it still build, do the unit tests still pass, does it still work?
BUG=14610
Review URL: http://codereview.chromium.org/243100

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@28016 0039d316-1c4b-4281-b951-d872f2087c98

3 files changed, 101 insertions, 0 deletions

diff --git a/base/base.gyp b/base/base.gyp
index 47818f5..bedc304 100644
--- a/base/base.gyp
+++ b/base/base.gyp
@@ -196,6 +196,8 @@
         'native_library_win.cc',
         'non_thread_safe.cc',
         'non_thread_safe.h',
+        'nsimage_cache_mac.h',
+        'nsimage_cache_mac.mm',
         'nss_init.cc',
         'nss_init.h',
         'nullable_string16.h',
diff --git a/base/nsimage_cache_mac.h b/base/nsimage_cache_mac.h
new file mode 100644
index 0000000..ffa8dbb
--- /dev/null
+++ b/base/nsimage_cache_mac.h
@@ -0,0 +1,32 @@
+// Copyright (c) 2009 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef BASE_NSIMAGE_CACHE_MAC_H_
+#define BASE_NSIMAGE_CACHE_MAC_H_
+
+#ifdef __OBJC__
+@class NSImage;
+@class NSString;
+#else
+class NSImage;
+class NSString;
+#endif
+
+namespace nsimage_cache {
+
+// Returns an autoreleased image from the main app bundle
+// (mac_util::MainAppBundle()) with the given name, and keeps it in memory so
+// future fetches are fast.
+// NOTE:
+//   - This should only be called on the main thread.
+//   - The caller should retain the image if they want to keep it around, as
+//     the cache could have limit on size/lifetime, etc.
+NSImage* ImageNamed(NSString* name);
+
+// Clears the cache.
+void Clear(void);
+
+}  // namespace nsimage_cache
+
+#endif  // BASE_NSIMAGE_CACHE_MAC_H_
diff --git a/base/nsimage_cache_mac.mm b/base/nsimage_cache_mac.mm
new file mode 100644
index 0000000..7ca05be
--- /dev/null
+++ b/base/nsimage_cache_mac.mm
@@ -0,0 +1,67 @@
+// Copyright (c) 2009 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "base/nsimage_cache_mac.h"
+
+#import <AppKit/AppKit.h>
+
+#include "base/logging.h"
+#include "base/mac_util.h"
+
+// When C++ exceptions are disabled, the C++ library defines |try| and
+// |catch| so as to allow exception-expecting C++ code to build properly when
+// language support for exceptions is not present.  These macros interfere
+// with the use of |@try| and |@catch| in Objective-C files such as this one.
+// Undefine these macros here, after everything has been #included, since
+// there will be no C++ uses and only Objective-C uses from this point on.
+#undef try
+#undef catch
+
+namespace nsimage_cache {
+
+static NSMutableDictionary* image_cache = nil;
+
+NSImage* ImageNamed(NSString* name) {
+  DCHECK(name);
+
+  // NOTE: to make this thread safe, we'd have to sync on the cache and
+  // also force all the bundle calls on the main thread.
+
+  if (!image_cache) {
+    image_cache = [[NSMutableDictionary alloc] init];
+    DCHECK(image_cache);
+  }
+
+  NSImage* result = [image_cache objectForKey:name];
+  if (!result) {
+    DLOG_IF(INFO, [[name pathExtension] length] == 0)
+        << "Suggest including the extension in the image name";
+
+    NSString* path = [mac_util::MainAppBundle() pathForImageResource:name];
+    if (path) {
+      @try {
+        result = [[[NSImage alloc] initWithContentsOfFile:path] autorelease];
+        if (result)
+          [image_cache setObject:result forKey:name];
+      }
+      @catch (id err) {
+        DLOG(ERROR) << "Failed to load the image for name '"
+            << [name UTF8String] << "' from path '" << [path UTF8String]
+            << "', error: " << [err description];
+        result = nil;
+      }
+    }
+  }
+
+  // TODO: if we ever limit the cache size, this should retain & autorelease
+  // the image.
+  return result;
+}
+
+void Clear(void) {
+  // NOTE: to make this thread safe, we'd have to sync on the cache.
+  [image_cache removeAllObjects];
+}
+
+}  // namespace nsimage_cache