Fix some build symbol configuration.

Remove -gdwarf-4 from GYP build. This is the default for GCC 4.8 which is now required, so this command-line argument is redundant.

Only set use_debug_fission in the GN build in debug mode. This matches GYP. Release mode symbols will be non-fission.

Implement linux_symbols target in GN. Convert dump_app_syms from sh to Python for better GN usability, and it's more readable for normal programmers on the team.

Reland of https://codereview.chromium.org/1182663007/
Reland of https://codereview.chromium.org/1179393004/
TBR=thakis@chromium.org

Review URL: https://codereview.chromium.org/1197793002

Cr-Commit-Position: refs/heads/master@{#335370}

1 files changed, 36 insertions, 0 deletions

diff --git a/chrome/BUILD.gn b/chrome/BUILD.gn
index 0d3d801..e33713b 100644
--- a/chrome/BUILD.gn
+++ b/chrome/BUILD.gn
@@ -806,4 +806,40 @@ if (is_linux) {
       "-e s/@@CONFDIR@@/$confdir/",
     ]
   }
+
+  action("linux_symbols") {
+    script = "//build/linux/dump_app_syms.py"
+
+    dump_syms_label = "//breakpad:dump_syms($host_toolchain)"
+    dump_syms_binary =
+        get_label_info(dump_syms_label, "root_out_dir") + "/" + "dump_syms"
+
+    chrome_binary = "$root_out_dir/chrome"
+    if (current_cpu == "x86") {
+      # Use "ia32" instead of "x86" for GYP compat.
+      symbol_file = "$root_out_dir/chrome.breakpad.ia32"
+    } else {
+      symbol_file = "$root_out_dir/chrome.breakpad.$current_cpu"
+    }
+
+    inputs = [
+      chrome_binary,
+      dump_syms_binary,
+    ]
+    outputs = [
+      symbol_file,
+    ]
+
+    args = [
+      "./" + rebase_path(dump_syms_binary, root_build_dir),
+      "0",  # TODO(GYP) This is linux_strip_binary if it is needed.
+      rebase_path(chrome_binary, root_build_dir),
+      rebase_path(symbol_file, root_build_dir),
+    ]
+
+    deps = [
+      ":chrome",
+      dump_syms_label,
+    ]
+  }
 }