Add a unit test for BaseView. Add a helper to get the contentView more easily.

Review URL: http://codereview.chromium.org/82001

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@14030 0039d316-1c4b-4281-b951-d872f2087c98

3 files changed, 60 insertions, 1 deletions

diff --git a/chrome/browser/cocoa/base_view_unittest.mm b/chrome/browser/cocoa/base_view_unittest.mm
new file mode 100644
index 0000000..07d0574
--- /dev/null
+++ b/chrome/browser/cocoa/base_view_unittest.mm
@@ -0,0 +1,58 @@
+// Copyright (c) 2009 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import <Cocoa/Cocoa.h>
+
+#include "base/scoped_nsobject.h"
+#import "chrome/browser/cocoa/base_view.h"
+#import "chrome/browser/cocoa/cocoa_test_helper.h"
+#include "testing/gtest/include/gtest/gtest.h"
+
+namespace {
+
+class BaseViewTest : public testing::Test {
+ public:
+  BaseViewTest() {
+    NSRect frame = NSMakeRect(0, 0, 100, 100);
+    view_.reset([[BaseView alloc] initWithFrame:frame]);
+    [cocoa_helper_.contentView() addSubview:view_.get()];
+  }
+
+  scoped_nsobject<BaseView> view_;
+  CocoaTestHelper cocoa_helper_;  // Inits Cocoa, creates window, etc...
+};
+
+// Test adding/removing from the view hierarchy, mostly to ensure nothing
+// leaks or crashes.
+TEST_F(BaseViewTest, AddRemove) {
+  EXPECT_EQ(cocoa_helper_.contentView(), [view_ superview]);
+  [view_.get() removeFromSuperview];
+  EXPECT_FALSE([view_ superview]);
+}
+
+// Test drawing, mostly to ensure nothing leaks or crashes.
+TEST_F(BaseViewTest, Display) {
+  [view_ display];
+}
+
+// Convert a rect in |view_|'s Cocoa coordinate system to gfx::Rect's top-left
+// coordinate system. Repeat the process in reverse and make sure we come out
+// with the original rect.
+TEST_F(BaseViewTest, NSRectToRect) {
+  NSRect convert = NSMakeRect(10, 10, 50, 50);
+  gfx::Rect converted = [view_ NSRectToRect:convert];
+  EXPECT_EQ(converted.x(), 10);
+  EXPECT_EQ(converted.y(), 40);  // Due to view being 100px tall.
+  EXPECT_EQ(converted.width(), convert.size.width);
+  EXPECT_EQ(converted.height(), convert.size.height);
+
+  // Go back the other way.
+  NSRect back_again = [view_ RectToNSRect:converted];
+  EXPECT_EQ(back_again.origin.x, convert.origin.x);
+  EXPECT_EQ(back_again.origin.y, convert.origin.y);
+  EXPECT_EQ(back_again.size.width, convert.size.width);
+  EXPECT_EQ(back_again.size.height, convert.size.height);
+}
+
+}  // namespace
diff --git a/chrome/browser/cocoa/bookmark_bar_controller_unittest.mm b/chrome/browser/cocoa/bookmark_bar_controller_unittest.mm
index f9abec5..543a5b3 100644
--- a/chrome/browser/cocoa/bookmark_bar_controller_unittest.mm
+++ b/chrome/browser/cocoa/bookmark_bar_controller_unittest.mm
@@ -22,7 +22,7 @@ class BookmarkBarControllerTest : public testing::Test {
     bar_.reset(
         [[BookmarkBarController alloc] initWithProfile:helper_.GetProfile()
                                            contentArea:content_area_.get()]);
-    NSView* parent = [cocoa_helper_.window() contentView];
+    NSView* parent = cocoa_helper_.contentView();
     [parent addSubview:content_area_.get()];
     [parent addSubview:[bar_ view]];
   }
diff --git a/chrome/browser/cocoa/cocoa_test_helper.h b/chrome/browser/cocoa/cocoa_test_helper.h
index 04fd2de5..28515276 100644
--- a/chrome/browser/cocoa/cocoa_test_helper.h
+++ b/chrome/browser/cocoa/cocoa_test_helper.h
@@ -51,6 +51,7 @@ class CocoaTestHelper {
 
   // Access the Cocoa window created for the test.
   NSWindow* window() const { return window_.get(); }
+  NSView* contentView() const { return [window_ contentView]; }
 
  private:
   scoped_nsobject<NSWindow> window_;