Add GN build file for components/storage_monitor

A line-by-line conversion of the existing GYP configs.

R=ajwong
TBR=gbillock

Review URL: https://codereview.chromium.org/387773003

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@283007 0039d316-1c4b-4281-b951-d872f2087c98

3 files changed, 124 insertions, 0 deletions

diff --git a/components/BUILD.gn b/components/BUILD.gn
index b8e9daa..b51f697 100644
--- a/components/BUILD.gn
+++ b/components/BUILD.gn
@@ -101,4 +101,10 @@ group("all_components") {
       "//components/web_modal",  # Blocked on content.
     ]
   }
+
+  if (!is_ios && !is_android) {
+    deps += [
+      "//components/storage_monitor",
+    ]
+  }
 }
diff --git a/components/storage_monitor.gypi b/components/storage_monitor.gypi
index e43cf4c..e522e8d 100644
--- a/components/storage_monitor.gypi
+++ b/components/storage_monitor.gypi
@@ -5,6 +5,7 @@
 {
   'targets': [
     {
+      # GN version: //components/storage_monitor
       'target_name': 'storage_monitor',
       'type': 'static_library',
       'include_dirs': [
@@ -88,6 +89,7 @@
       ],
     },
     {
+      # GN version: //components/storage_monitor:test_support
       'target_name': 'storage_monitor_test_support',
       'type': 'static_library',
       'include_dirs': [
diff --git a/components/storage_monitor/BUILD.gn b/components/storage_monitor/BUILD.gn
new file mode 100644
index 0000000..d0404c9
--- /dev/null
+++ b/components/storage_monitor/BUILD.gn
@@ -0,0 +1,116 @@
+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/features.gni")
+
+# GYP version: components/storage_monitor.gypi:storage_monitor
+static_library("storage_monitor") {
+  sources = [
+    "image_capture_device.h",
+    "image_capture_device.mm",
+    "image_capture_device_manager.h",
+    "image_capture_device_manager.mm",
+    "media_storage_util.cc",
+    "media_storage_util.h",
+    "media_transfer_protocol_device_observer_linux.cc",
+    "media_transfer_protocol_device_observer_linux.h",
+    "mtab_watcher_linux.cc",
+    "mtab_watcher_linux.h",
+    "portable_device_watcher_win.cc",
+    "portable_device_watcher_win.h",
+    "removable_device_constants.cc",
+    "removable_device_constants.h",
+    "removable_storage_observer.h",
+    "storage_info.cc",
+    "storage_info.h",
+    "storage_monitor.cc",
+    "storage_monitor.h",
+    "storage_monitor_chromeos.cc",
+    "storage_monitor_chromeos.h",
+    "storage_monitor_linux.cc",
+    "storage_monitor_linux.h",
+    "storage_monitor_mac.h",
+    "storage_monitor_mac.mm",
+    "storage_monitor_win.cc",
+    "storage_monitor_win.h",
+    "transient_device_ids.cc",
+    "transient_device_ids.h",
+    "udev_util_linux.cc",
+    "udev_util_linux.h",
+    "volume_mount_watcher_win.cc",
+    "volume_mount_watcher_win.h",
+  ]
+
+  deps = [
+    "//base",
+  ]
+
+  if (is_mac) {
+    libs += [
+      "DiskArbitration.framework",
+      "Foundation.framework",
+      "ImageCaptureCore.framework",
+    ]
+  }
+
+  if (is_linux) {
+    deps += [
+      "//device/media_transfer_protocol",
+      "//device/media_transfer_protocol:mtp_file_entry_proto",
+      "//device/media_transfer_protocol:mtp_storage_info_proto",
+    ]
+  }
+
+  if (use_udev) {
+    deps += [
+      "//device/udev_linux",
+    ]
+  } else {
+    sources -= [
+      "storage_monitor_linux.cc",
+      "storage_monitor_linux.h",
+      "udev_util_linux.cc",
+      "udev_util_linux.h",
+    ]
+  }
+
+  if (is_chromeos) {
+    sources -= [
+      "mtab_watcher_linux.cc",
+      "mtab_watcher_linux.h",
+      "storage_monitor_linux.cc",
+      "storage_monitor_linux.h",
+    ]
+  }
+}
+
+# GYP version: components/storage_monitor.gypi:storage_monitor_test_support
+static_library("test_support") {
+  sources = [
+    "mock_removable_storage_observer.cc",
+    "mock_removable_storage_observer.h",
+    "test_media_transfer_protocol_manager_linux.cc",
+    "test_media_transfer_protocol_manager_linux.h",
+    "test_portable_device_watcher_win.cc",
+    "test_portable_device_watcher_win.h",
+    "test_storage_monitor.cc",
+    "test_storage_monitor.h",
+    "test_storage_monitor_win.cc",
+    "test_storage_monitor_win.h",
+    "test_volume_mount_watcher_win.cc",
+    "test_volume_mount_watcher_win.h",
+  ]
+
+  deps = [
+    "//base",
+    ":storage_monitor",
+  ]
+
+  if (is_linux) {
+    deps += [
+      "//device/media_transfer_protocol",
+      "//device/media_transfer_protocol:mtp_file_entry_proto",
+    ]
+  }
+}