Add support for multi resolution icons

To support HiDPI we need a way to load two copies of icons, a low resolution version and a high resolution version.

To support this, this change does the following:
  - split theme_resource.grd into three files:
      - theme_resources.grd: icons that only have one resolution
      - theme_resources_standard.grd: low resolution icons
      - theme_resources_large.grd: high resolution icons
   - theme_resource.grd and theme_resources_standard.grd and compiled into chrome.pak/chrome.rc for all platforms.
   - theme_resources_large.grd is compiled into theme_resources_large.pak for platforms that want high resolution icons (currently only Mac)
   - gfx::Image now support icons with multiple resolution

Currently not all ThemeService APIs return multi-resolution images. Once this is checked in I'll work on converting them as I go.

Note, this change will have to be coordinated with the change to reorganize theme resources. I'll work with saintlou on that.

BUG=75812
TEST=Added a TIFF to theme_resources.grd. Verified that the toolbar icon had a mutliresolution image. Verified that unit tests passed.

Review URL: http://codereview.chromium.org/6849030

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@82185 0039d316-1c4b-4281-b951-d872f2087c98

3 files changed, 178 insertions, 36 deletions

diff --git a/skia/ext/skia_utils_mac.h b/skia/ext/skia_utils_mac.h
index 0551643..04d4a1d 100644
--- a/skia/ext/skia_utils_mac.h
+++ b/skia/ext/skia_utils_mac.h
@@ -7,6 +7,7 @@
 #pragma once
 
 #include <CoreGraphics/CGColor.h>
+#include <vector>
 
 #include "third_party/skia/include/core/SkColor.h"
 
@@ -23,8 +24,10 @@ typedef struct _NSSize NSSize;
 
 #ifdef __OBJC__
 @class NSImage;
+@class NSImageRep;
 #else
 class NSImage;
+class NSImageRep;
 #endif
 
 namespace gfx {
@@ -64,6 +67,9 @@ SkBitmap CGImageToSkBitmap(CGImageRef image);
 // Draws an NSImage with a given size into a SkBitmap.
 SkBitmap NSImageToSkBitmap(NSImage* image, NSSize size, bool is_opaque);
 
+// Draws an NSImageRep with a given size into a SkBitmap.
+SkBitmap NSImageRepToSkBitmap(NSImageRep* image, NSSize size, bool is_opaque);
+
 // Given an SkBitmap and a color space, return an autoreleased NSImage.
 NSImage* SkBitmapToNSImageWithColorSpace(const SkBitmap& icon,
                                          CGColorSpaceRef colorSpace);
@@ -73,6 +79,10 @@ NSImage* SkBitmapToNSImageWithColorSpace(const SkBitmap& icon,
 // TODO(thakis): Remove this -- http://crbug.com/69432
 NSImage* SkBitmapToNSImage(const SkBitmap& icon);
 
+// Given a vector of SkBitmaps, return an NSImage with each bitmap added
+// as a representation.
+NSImage* SkBitmapsToNSImage(const std::vector<const SkBitmap*>& bitmaps);
+
 // Returns |[NSImage imageNamed:@"NSApplicationIcon"]| as SkBitmap.
 SkBitmap AppplicationIconAtSize(int size);
 
diff --git a/skia/ext/skia_utils_mac.mm b/skia/ext/skia_utils_mac.mm
index c78121a..2ecb3f2 100644
--- a/skia/ext/skia_utils_mac.mm
+++ b/skia/ext/skia_utils_mac.mm
@@ -8,6 +8,7 @@
 
 #include "base/logging.h"
 #include "base/mac/scoped_cftyperef.h"
+#include "base/memory/scoped_nsobject.h"
 #include "base/memory/scoped_ptr.h"
 #include "skia/ext/bitmap_platform_device_mac.h"
 #include "third_party/skia/include/utils/mac/SkCGUtils.h"
@@ -116,15 +117,20 @@ SkBitmap CGImageToSkBitmap(CGImageRef image) {
 }
 
 SkBitmap NSImageToSkBitmap(NSImage* image, NSSize size, bool is_opaque) {
+  return NSImageRepToSkBitmap([image bestRepresentationForDevice:nil],
+                              size, is_opaque);
+}
+
+SkBitmap NSImageRepToSkBitmap(NSImageRep* image, NSSize size, bool is_opaque) {
   SkBitmap bitmap;
   bitmap.setConfig(SkBitmap::kARGB_8888_Config, size.width, size.height);
-  if (bitmap.allocPixels() != true)
+  if (!bitmap.allocPixels())
     return bitmap;  // Return |bitmap| which should respond true to isNull().
 
   bitmap.setIsOpaque(is_opaque);
 
   base::mac::ScopedCFTypeRef<CGColorSpaceRef> color_space(
-    CGColorSpaceCreateWithName(kCGColorSpaceGenericRGB));
+      CGColorSpaceCreateWithName(kCGColorSpaceGenericRGB));
   void* data = bitmap.getPixels();
 
   // Allocate a bitmap context with 4 components per pixel (BGRA). Apple
@@ -145,21 +151,18 @@ SkBitmap NSImageToSkBitmap(NSImage* image, NSSize size, bool is_opaque) {
 #undef HAS_ARGB_SHIFTS
 
   // Something went really wrong. Best guess is that the bitmap data is invalid.
-  DCHECK(context != NULL);
+  DCHECK(context);
 
   // Save the current graphics context so that we can restore it later.
   [NSGraphicsContext saveGraphicsState];
 
   // Dummy context that we will draw into.
   NSGraphicsContext* context_cocoa =
-    [NSGraphicsContext graphicsContextWithGraphicsPort:context flipped:NO];
+      [NSGraphicsContext graphicsContextWithGraphicsPort:context flipped:NO];
   [NSGraphicsContext setCurrentContext:context_cocoa];
 
   // This will stretch any images to |size| if it does not fit or is non-square.
-  [image drawInRect:NSMakeRect(0, 0, size.width, size.height)
-           fromRect:NSZeroRect
-          operation:NSCompositeCopy
-           fraction:1.0];
+  [image drawInRect:NSMakeRect(0, 0, size.width, size.height)];
 
   // Done drawing, restore context.
   [NSGraphicsContext restoreGraphicsState];
@@ -173,13 +176,12 @@ NSImage* SkBitmapToNSImageWithColorSpace(const SkBitmap& skiaBitmap,
     return nil;
 
   // First convert SkBitmap to CGImageRef.
-  CGImageRef cgimage =
-    SkCreateCGImageRefWithColorspace(skiaBitmap, colorSpace);
+  base::mac::ScopedCFTypeRef<CGImageRef> cgimage(
+      SkCreateCGImageRefWithColorspace(skiaBitmap, colorSpace));
 
   // Now convert to NSImage.
-  NSBitmapImageRep* bitmap = [[[NSBitmapImageRep alloc]
-                                   initWithCGImage:cgimage] autorelease];
-  CFRelease(cgimage);
+  scoped_nsobject<NSBitmapImageRep> bitmap(
+      [[NSBitmapImageRep alloc] initWithCGImage:cgimage]);
   NSImage* image = [[[NSImage alloc] init] autorelease];
   [image addRepresentation:bitmap];
   [image setSize:NSMakeSize(skiaBitmap.width(), skiaBitmap.height())];
@@ -192,6 +194,37 @@ NSImage* SkBitmapToNSImage(const SkBitmap& skiaBitmap) {
   return SkBitmapToNSImageWithColorSpace(skiaBitmap, colorSpace.get());
 }
 
+NSImage* SkBitmapsToNSImage(const std::vector<const SkBitmap*>& bitmaps) {
+  if (bitmaps.empty())
+    return nil;
+
+  base::mac::ScopedCFTypeRef<CGColorSpaceRef> color_space(
+      CGColorSpaceCreateWithName(kCGColorSpaceGenericRGB));
+  NSImage* image = [[[NSImage alloc] init] autorelease];
+  NSSize min_size = NSZeroSize;
+
+  for (std::vector<const SkBitmap*>::const_iterator it = bitmaps.begin();
+       it != bitmaps.end(); ++it) {
+    const SkBitmap& skiaBitmap = **it;
+    // First convert SkBitmap to CGImageRef.
+    base::mac::ScopedCFTypeRef<CGImageRef> cgimage(
+        SkCreateCGImageRefWithColorspace(skiaBitmap, color_space));
+
+    // Now convert to NSImage.
+    scoped_nsobject<NSBitmapImageRep> bitmap(
+        [[NSBitmapImageRep alloc] initWithCGImage:cgimage]);
+    [image addRepresentation:bitmap];
+
+    if (min_size.width == 0 || min_size.width > skiaBitmap.width()) {
+      min_size.width = skiaBitmap.width();
+      min_size.height = skiaBitmap.height();
+    }
+  }
+
+  [image setSize:min_size];
+  return image;
+}
+
 SkBitmap AppplicationIconAtSize(int size) {
   NSImage* image = [NSImage imageNamed:@"NSApplicationIcon"];
   return NSImageToSkBitmap(image, NSMakeSize(size, size), /* is_opaque=*/true);
diff --git a/skia/ext/skia_utils_mac_unittest.mm b/skia/ext/skia_utils_mac_unittest.mm
index 1726c4a..c86be98 100644
--- a/skia/ext/skia_utils_mac_unittest.mm
+++ b/skia/ext/skia_utils_mac_unittest.mm
@@ -9,39 +9,60 @@ namespace {
 
 class SkiaUtilsMacTest : public testing::Test {
  public:
+  // Creates a red or blue bitmap.
+  SkBitmap CreateSkBitmap(int width, int height, bool isred, bool tfbit);
+
+  // Creates a red or blue image.
+  NSImage* CreateNSImage(int width, int height, bool isred);
+
+  // Checks that the given bitmap rep is actually red or blue.
+  void TestImageRep(NSBitmapImageRep* imageRep, bool isred);
+
+  // Checks that the given bitmap is actually red or blue.
+  void TestSkBitmap(const SkBitmap& bitmap, bool isred);
+
   // If not red, is blue.
   // If not tfbit (twenty-four-bit), is 444.
   void ShapeHelper(int width, int height, bool isred, bool tfbit);
 };
 
-void SkiaUtilsMacTest::ShapeHelper(int width, int height,
-                                   bool isred, bool tfbit) {
-  SkBitmap thing;
+SkBitmap SkiaUtilsMacTest::CreateSkBitmap(int width, int height,
+                                          bool isred, bool tfbit) {
+  SkBitmap bitmap;
 
   if (tfbit)
-    thing.setConfig(SkBitmap::kARGB_8888_Config, width, height);
+    bitmap.setConfig(SkBitmap::kARGB_8888_Config, width, height);
   else
-    thing.setConfig(SkBitmap::kARGB_4444_Config, width, height);
-  thing.allocPixels();
+    bitmap.setConfig(SkBitmap::kARGB_4444_Config, width, height);
+  bitmap.allocPixels();
 
   if (isred)
-    thing.eraseRGB(0xff, 0, 0);
+    bitmap.eraseRGB(0xff, 0, 0);
   else
-    thing.eraseRGB(0, 0, 0xff);
+    bitmap.eraseRGB(0, 0, 0xff);
 
-  // Confirm size
-  NSImage* image = gfx::SkBitmapToNSImage(thing);
-  EXPECT_DOUBLE_EQ([image size].width, (double)width);
-  EXPECT_DOUBLE_EQ([image size].height, (double)height);
+  return bitmap;
+}
 
-  // Get the color of a pixel and make sure it looks fine
+NSImage* SkiaUtilsMacTest::CreateNSImage(int width, int height, bool isred) {
+  NSImage* image = [[[NSImage alloc] initWithSize:NSMakeSize(width, height)]
+      autorelease];
   [image lockFocus];
+  if (isred)
+    [[NSColor colorWithDeviceRed:1.0 green:0.0 blue:0.0 alpha:1.0] set];
+  else
+    [[NSColor colorWithDeviceRed:0.0 green:0.0 blue:1.0 alpha:1.0] set];
+  NSRectFill(NSMakeRect(0, 0, width, height));
+  [image unlockFocus];
+  return image;
+}
 
-  int x = width > 17 ? 17 : 0;
-  int y = height > 17 ? 17 : 0;
-  NSColor* color = NSReadPixel(NSMakePoint(x, y));
+void SkiaUtilsMacTest::TestImageRep(NSBitmapImageRep* imageRep, bool isred) {
+  // Get the color of a pixel and make sure it looks fine
+  int x = [imageRep size].width > 17 ? 17 : 0;
+  int y = [imageRep size].height > 17 ? 17 : 0;
+  NSColor* color = [imageRep colorAtX:x y:y];
   CGFloat red = 0, green = 0, blue = 0, alpha = 0;
-  [image unlockFocus];
 
   // SkBitmapToNSImage returns a bitmap in the calibrated color space (sRGB),
   // while NSReadPixel returns a color in the device color space. Convert back
@@ -52,14 +73,47 @@ void SkiaUtilsMacTest::ShapeHelper(int width, int height,
 
   // Be tolerant of floating point rounding and lossy color space conversions.
   if (isred) {
-    EXPECT_GT(red, 0.95);
-    EXPECT_LT(blue, 0.05);
+    EXPECT_NEAR(red, 1.0, 0.025);
+    EXPECT_NEAR(blue, 0.0, 0.025);
+  } else {
+    EXPECT_NEAR(red, 0.0, 0.025);
+    EXPECT_NEAR(blue, 1.0, 0.025);
+  }
+  EXPECT_NEAR(green, 0.0, 0.025);
+  EXPECT_NEAR(alpha, 1.0, 0.025);
+}
+
+void SkiaUtilsMacTest::TestSkBitmap(const SkBitmap& bitmap, bool isred) {
+  int x = bitmap.width() > 17 ? 17 : 0;
+  int y = bitmap.height() > 17 ? 17 : 0;
+  SkColor color = bitmap.getColor(x, y);
+
+  // Due to colorspace issues the colors may not match exactly.
+  // TODO(sail): Need to fix this, http://crbug.com/79946
+  if (isred) {
+    EXPECT_NEAR(255u, SkColorGetR(color), 20);
+    EXPECT_NEAR(0u, SkColorGetB(color), 20);
   } else {
-    EXPECT_LT(red, 0.05);
-    EXPECT_GT(blue, 0.95);
+    EXPECT_NEAR(0u, SkColorGetR(color), 20);
+    EXPECT_NEAR(255u, SkColorGetB(color), 20);
   }
-  EXPECT_LT(green, 0.05);
-  EXPECT_GT(alpha, 0.95);
+  EXPECT_NEAR(0u, SkColorGetG(color), 20);
+  EXPECT_NEAR(255u, SkColorGetA(color), 20);
+}
+
+void SkiaUtilsMacTest::ShapeHelper(int width, int height,
+                                   bool isred, bool tfbit) {
+  SkBitmap thing(CreateSkBitmap(width, height, isred, tfbit));
+
+  // Confirm size
+  NSImage* image = gfx::SkBitmapToNSImage(thing);
+  EXPECT_DOUBLE_EQ([image size].width, (double)width);
+  EXPECT_DOUBLE_EQ([image size].height, (double)height);
+
+  EXPECT_TRUE([[image representations] count] == 1);
+  EXPECT_TRUE([[[image representations] lastObject]
+      isKindOfClass:[NSBitmapImageRep class]]);
+  TestImageRep([[image representations] lastObject], isred);
 }
 
 TEST_F(SkiaUtilsMacTest, BitmapToNSImage_RedSquare64x64) {
@@ -74,4 +128,49 @@ TEST_F(SkiaUtilsMacTest, BitmapToNSImage_BlueRectangle444) {
   ShapeHelper(200, 200, false, false);
 }
 
+TEST_F(SkiaUtilsMacTest, MultipleBitmapsToNSImage) {
+  int redWidth = 10;
+  int redHeight = 15;
+  int blueWidth = 20;
+  int blueHeight = 30;
+
+  SkBitmap redBitmap(CreateSkBitmap(redWidth, redHeight, true, true));
+  SkBitmap blueBitmap(CreateSkBitmap(blueWidth, blueHeight, false, true));
+  std::vector<const SkBitmap*> bitmaps;
+  bitmaps.push_back(&redBitmap);
+  bitmaps.push_back(&blueBitmap);
+
+  NSImage* image = gfx::SkBitmapsToNSImage(bitmaps);
+
+  // Image size should be the same as the smallest bitmap.
+  EXPECT_DOUBLE_EQ(redWidth, [image size].width);
+  EXPECT_DOUBLE_EQ(redHeight, [image size].height);
+
+  EXPECT_EQ(2u, [[image representations] count]);
+
+  for (NSBitmapImageRep* imageRep in [image representations]) {
+    NSBitmapImageRep* imageRep = [[image representations] objectAtIndex:0];
+    bool isred = [imageRep size].width == redWidth;
+    if (isred) {
+      EXPECT_DOUBLE_EQ(redHeight, [imageRep size].height);
+    } else {
+      EXPECT_DOUBLE_EQ(blueWidth, [imageRep size].width);
+      EXPECT_DOUBLE_EQ(blueHeight, [imageRep size].height);
+    }
+    TestImageRep(imageRep, isred);
+  }
+}
+
+TEST_F(SkiaUtilsMacTest, NSImageRepToSkBitmap) {
+  int width = 10;
+  int height = 15;
+  bool isred = true;
+
+  NSImage* image = CreateNSImage(width, height, isred);
+  EXPECT_EQ(1u, [[image representations] count]);
+  NSBitmapImageRep* imageRep = [[image representations] lastObject];
+  SkBitmap bitmap(gfx::NSImageRepToSkBitmap(imageRep, [image size], false));
+  TestSkBitmap(bitmap, isred);
+}
+
 }  // namespace