SCons renaming updates for base, net and googleurl:

* Rename SConscript files to {module}.scons or {moduel}_lib.scons,
  depending on the primary target involved.
* Separate targets into individual *.scons files, with one
  construction environment (named "env") per *.scons file.
* Add using_{module}.scons files (like .vsprops) that will be used
  by other modules to add CPPDEFINES, CPPPATH, LIBS and LIBPATH values.
* Update other modules' *.scons files to use the new using_{module}.scons
  files (using a temporary one-liner idiom until we have the
  ApplySConscript() method from the Hammer modules).
* Use the idiom of removing to-be-ported files from the master list,
  so they can be simply deleted from the to-be-ported list as they
  get ported in the future, instead of having to shuffle entries
  between lists.
* Use $OBJ_ROOT instead of hard-coded '#/$BUILD_TYPE/' for the $*_DIR
  variables.
* Add a addRepository() call mapping build/ to $TARGET_ROOT/googleurl,
  so its $OBJ_ROOT value can look like the others'.
* Formatting changes, primarily modifying indentation to conform to
  style guidelines.
* Fix copyright headers in some third_party/* modules
  previously overlooked.
* Add rudimentary __doc__ strings, setting up for a future
  ability to generate meaningful documentation.


Review URL: http://codereview.chromium.org/7807

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@3675 0039d316-1c4b-4281-b951-d872f2087c98

1 files changed, 76 insertions, 0 deletions

diff --git a/third_party/libevent/libevent.scons b/third_party/libevent/libevent.scons
new file mode 100644
index 0000000..82e54ce
--- /dev/null
+++ b/third_party/libevent/libevent.scons
@@ -0,0 +1,76 @@
+# Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+
+__doc__ = """
+Configuration for building event.lib / libevent.a.
+
+This is currently only suitable for Linux and Mac.
+"""
+
+Import('env')
+
+env = env.Clone()
+
+env.Append(
+    CPPDEFINES = [
+        'HAVE_CONFIG_H',
+    ],
+)
+
+if env['PLATFORM'] == 'darwin':
+  env.Prepend(
+      CPPPATH = [
+          '$LIBEVENT_DIR/generated/',
+      ],
+  )
+  env['ENV']['CONFIGURATION_TEMP_DIR'] = env.Dir('$LIBEVENT_DIR').abspath
+  env.Command('$LIBEVENT_DIR/generated/config.h',
+              ['libevent.xcodeproj/libevent_prebuild.sh', 'config.h.in'],
+              'sh ${SOURCES[0]} ${SOURCES[1]}')
+    
+
+if env['PLATFORM'] == 'posix':
+  env.Prepend(
+      CPPPATH = [
+          '$LIBEVENT_DIR/linux/',
+      ],
+  )
+
+env.Prepend(
+    CPPPATH = [
+        '$LIBEVENT_DIR',
+        '$LIBEVENT_DIR/compat/',
+    ],
+)
+
+input_files = [
+    'buffer.c',
+    'evbuffer.c',
+    'evdns.c',
+    'event.c',
+    'event_tagging.c',
+    'evrpc.c',
+    'evutil.c',
+    'http.c',
+    'log.c',
+    'poll.c',
+    'select.c',
+    'signal.c',
+    'strlcpy.c',
+]
+
+if env['PLATFORM'] == 'posix':
+  input_files.extend([
+      'epoll.c',
+      'epoll_sub.c',
+  ])
+
+if env['PLATFORM'] == 'darwin':
+  input_files.extend([
+      'kqueue.c',
+  ])
+
+
+env.ChromeStaticLibrary('event', input_files)