# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Browser test resource files.
media_router_integration_test_resources = [
  "resources/basic_test.html",
  "resources/close_route_with_error_on_send.json",
  "resources/common.js",
  "resources/fail_create_route.json",
  "resources/fail_reconnect_session.html",
  "resources/fail_reconnect_session.json",
  "resources/no_provider.json",
  "resources/route_creation_timed_out.json",
]

# GYP version: chrome/test/media_router/media_router_tests.gypi:
# media_router_integration_test_files
copy("browser_tests_resource_files") {
  # This list corresponds to media_router_integration_test_resources in
  # media_router_integration_test_files target in GYP.
  sources = media_router_integration_test_resources
  outputs = [
    "$root_out_dir/media_router/browser_test_resources/{{source_file_part}}",
  ]
}

source_set("media_router_browsertests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [
    "media_router_base_browsertest.cc",
    "media_router_base_browsertest.h",
    "media_router_e2e_browsertest.cc",
    "media_router_e2e_browsertest.h",
    "media_router_e2e_ui_browsertest.cc",
    "media_router_integration_browsertest.cc",
    "media_router_integration_browsertest.h",
    "media_router_integration_ui_browsertest.cc",
    "test_media_sinks_observer.cc",
    "test_media_sinks_observer.h",
  ]
  deps = [
    ":browser_tests_resource_files",
    "//chrome/browser/media/router:test_support",
    "//chrome/test:test_support",
    "//chrome/test:test_support_ui",
    "//skia",
    "//testing/gtest",
  ]
}