# Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

Import('env')

env = env.Clone()

env.ApplySConscript([
    '$BASE_DIR/using_base.scons',
    '$BASE_DIR/gfx/using_base_gfx.scons',
    '$ICU38_DIR/using_icu38.scons',
    '$LIBPNG_DIR/using_libpng.scons',
    '$SKIA_DIR/using_skia.scons',
    '$ZLIB_DIR/using_zlib.scons',
])

env.Prepend(
    CPPPATH = [
        '$CHROME_SRC_DIR',
    ],
)

if env.Bit('windows'):
    env.Prepend(
        LINKFLAGS = [
            '/INCREMENTAL',
            '/DEBUG',

            '/DELAYLOAD:"dwmapi.dll"',
            '/DELAYLOAD:"uxtheme.dll"',

            '/SUBSYSTEM:CONSOLE',

            '/MACHINE:X86',
            '/FIXED:No',

            '/safeseh',
            '/dynamicbase',
            '/ignore:4199',
            '/nxcompat',
        ],
    )

input_files = ChromeFileList([
    'image_diff.cc',
])

env.ChromeTestProgram('image_diff', input_files)

p = env.ChromeMSVSProject('image_diff.vcproj',
                          dest=('$CHROME_SRC_DIR/chrome/'
                                + 'tools/test/image_diff/image_diff.vcproj'),
                          guid='{50B079C7-CD01-42D3-B8C4-9F8D9322E822}',
                          keyword='Win32Proj',
                          dependencies = [
                              '$BASE_DIR/build/base.vcproj',
                              '$ZLIB_DIR/zlib.vcproj',
                              '$ICU38_DIR/build/icu.vcproj',
                              '$BASE_DIR/build/base_gfx.vcproj',
                              '$LIBPNG_DIR/libpng.vcproj',
                              '$SKIA_DIR/skia.vcproj',
                          ],
                          # TODO(sgk):  when we can intuit the hierarchy
                          # from the built targets.
                          #buildtargets=TODO,
                          files=input_files,
                          relative_path_prefix='./',
                          tools=[
                              MSVSTool('VCLinkerTool',
                                       SubSystem='1'),
                              'VCCLCompilerTool',
                          ],
                          ConfigurationType='1')

p.AddConfig('Debug|Win32',
            InheritedPropertySheets=[
                '$(SolutionDir)../build/common.vsprops',
                '$(SolutionDir)../build/debug.vsprops',
                '$(SolutionDir)../third_party/libpng/using_libpng.vsprops',
                '$(SolutionDir)../third_party/zlib/using_zlib.vsprops',
            ])

p.AddConfig('Release|Win32',
            InheritedPropertySheets=[
                '$(SolutionDir)../build/common.vsprops',
                '$(SolutionDir)../build/release.vsprops',
                '$(SolutionDir)../third_party/libpng/using_libpng.vsprops',
                '$(SolutionDir)../third_party/zlib/using_zlib.vsprops',
            ])