# Copyright 2015 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")
import("//testing/test.gni")

static_library("arc") {
  sources = [
    "arc_bridge_bootstrap.cc",
    "arc_bridge_bootstrap.h",
    "arc_bridge_service.cc",
    "arc_bridge_service.h",
    "arc_bridge_service_impl.cc",
    "arc_bridge_service_impl.h",
    "arc_service.cc",
    "arc_service.h",
    "arc_service_manager.cc",
    "arc_service_manager.h",
    "auth/arc_auth_fetcher.cc",
    "auth/arc_auth_fetcher.h",
    "clipboard/arc_clipboard_bridge.cc",
    "clipboard/arc_clipboard_bridge.h",
    "crash_collector/arc_crash_collector_bridge.cc",
    "crash_collector/arc_crash_collector_bridge.h",
    "ime/arc_ime_ipc_host.h",
    "ime/arc_ime_ipc_host_impl.cc",
    "ime/arc_ime_ipc_host_impl.h",
    "ime/arc_ime_service.cc",
    "ime/arc_ime_service.h",
    "input/arc_input_bridge.cc",
    "input/arc_input_bridge.h",
    "metrics/arc_metrics_service.cc",
    "metrics/arc_metrics_service.h",
    "net/arc_net_host_impl.cc",
    "net/arc_net_host_impl.h",
    "power/arc_power_bridge.cc",
    "power/arc_power_bridge.h",
  ]

  deps = [
    "//ash:ash",
    "//base",
    "//chromeos",
    "//chromeos:power_manager_proto",
    "//components/exo",
    "//components/onc",
    "//components/prefs",
    "//components/signin/core/account_id",
    "//google_apis",
    "//ipc:ipc",
    "//ipc/mojo:mojo",
    "//mojo/edk/system",
    "//ui/arc",
    "//ui/aura",
    "//ui/base:base",
    "//ui/base/ime",
    "//ui/display:display",
    "//ui/events",
    "//ui/events:dom_keycode_converter",
  ]

  public_deps = [
    ":arc_bindings",
  ]
}

mojom("arc_bindings") {
  sources = [
    "common/app.mojom",
    "common/arc_bridge.mojom",
    "common/auth.mojom",
    "common/clipboard.mojom",
    "common/crash_collector.mojom",
    "common/ime.mojom",
    "common/input.mojom",
    "common/intent_helper.mojom",
    "common/net.mojom",
    "common/notifications.mojom",
    "common/policy.mojom",
    "common/power.mojom",
    "common/process.mojom",
    "common/video.mojom",
  ]
}

static_library("arc_test_support") {
  testonly = true
  sources = [
    "test/fake_app_instance.cc",
    "test/fake_app_instance.h",
    "test/fake_arc_bridge_bootstrap.cc",
    "test/fake_arc_bridge_bootstrap.h",
    "test/fake_arc_bridge_instance.cc",
    "test/fake_arc_bridge_instance.h",
    "test/fake_arc_bridge_service.cc",
    "test/fake_arc_bridge_service.h",
    "test/fake_notifications_instance.cc",
    "test/fake_notifications_instance.h",
  ]

  deps = [
    ":arc",
    ":arc_bindings",
    "//base",
    "//mojo/common:common_base",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "arc_bridge_service_unittest.cc",
    "ime/arc_ime_service_unittest.cc",
  ]

  deps = [
    ":arc",
    ":arc_bindings",
    ":arc_test_support",
    "//base",
    "//chromeos",
    "//ipc/mojo:mojo",
    "//mojo/public/cpp/system:system",
    "//testing/gtest",
    "//ui/aura",
    "//ui/base:test_support",
    "//ui/base/ime",
    "//ui/events",
    "//ui/events:dom_keycode_converter",
  ]
}

static_library("arc_standalone_service") {
  sources = [
    "standalone/service_helper.cc",
    "standalone/service_helper.h",
  ]

  deps = [
    "//base",
  ]
}

static_library("arc_standalone") {
  sources = [
    "standalone/arc_standalone_bridge_runner.cc",
    "standalone/arc_standalone_bridge_runner.h",
  ]

  deps = [
    ":arc",
    ":arc_standalone_service",
    "//base",
    "//ipc:ipc",
    "//ipc/mojo:mojo",
    "//mojo/edk/system",
  ]
}

test("arc_standalone_service_unittests") {
  sources = [
    "standalone/service_helper_unittest.cc",
  ]

  deps = [
    ":arc_standalone_service",
    "//base/test:test_support",
    "//testing/gtest",
  ]
}

executable("arc_standalone_bridge") {
  sources = [
    "standalone/arc_standalone_bridge_main.cc",
  ]

  deps = [
    ":arc_standalone",
    ":arc_standalone_service",
    "//base",
    "//ipc:ipc",
    "//ipc/mojo:mojo",
    "//mojo/edk/system",
  ]
}