# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

static_library("user_prefs_tracked") {
  sources = [
    "device_id.h",
    "device_id_mac.cc",
    "device_id_stub.cc",
    "device_id_win.cc",
    "dictionary_hash_store_contents.cc",
    "dictionary_hash_store_contents.h",
    "hash_store_contents.h",
    "interceptable_pref_filter.cc",
    "interceptable_pref_filter.h",
    "pref_hash_calculator.cc",
    "pref_hash_calculator.h",
    "pref_hash_filter.cc",
    "pref_hash_filter.h",
    "pref_hash_store.h",
    "pref_hash_store_impl.cc",
    "pref_hash_store_impl.h",
    "pref_hash_store_transaction.h",
    "pref_names.cc",
    "pref_names.h",
    "pref_service_hash_store_contents.cc",
    "pref_service_hash_store_contents.h",
    "segregated_pref_store.cc",
    "segregated_pref_store.h",
    "tracked_atomic_preference.cc",
    "tracked_atomic_preference.h",
    "tracked_preference.h",
    "tracked_preference_helper.cc",
    "tracked_preference_helper.h",
    "tracked_preference_histogram_names.cc",
    "tracked_preference_histogram_names.h",
    "tracked_preference_validation_delegate.h",
    "tracked_preferences_migration.cc",
    "tracked_preferences_migration.h",
    "tracked_split_preference.cc",
    "tracked_split_preference.h",
  ]

  if (is_win || (is_mac && !is_ios)) {
    sources -= [ "device_id_stub.cc" ]
  }

  if (is_ios) {
    sources -= [ "device_id_mac.cc" ]
  }

  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]

  deps = [
    "//base:base",
    "//components/pref_registry",
    "//components/prefs",
    "//crypto:crypto",
  ]
}

source_set("user_prefs_tracked_test_support") {
  testonly = true
  sources = [
    "mock_validation_delegate.cc",
    "mock_validation_delegate.h",
  ]

  deps = [
    ":user_prefs_tracked",
    "//base:base",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "device_id_unittest.cc",
    "pref_hash_calculator_unittest.cc",
    "pref_hash_filter_unittest.cc",
    "pref_hash_store_impl_unittest.cc",
    "pref_service_hash_store_contents_unittest.cc",
    "segregated_pref_store_unittest.cc",
    "tracked_preferences_migration_unittest.cc",
  ]

  deps = [
    ":user_prefs_tracked",
    ":user_prefs_tracked_test_support",
    "//base:base",
    "//components/prefs:test_support",
    "//testing/gtest",
  ]
}