# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/mojo/src/mojo/public/mojo_application.gni")
import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")

mojo_native_application("browser") {
  sources = [
    "main.cc",
  ]

  deps = [
    ":lib",
    "//mandoline/services/navigation/public/interfaces",
    "//mojo/application/public/cpp",
  ]
}

source_set("lib") {
  sources = [
    "browser.cc",
    "browser.h",
    "merged_service_provider.cc",
    "merged_service_provider.h",
    "navigator_host_impl.cc",
    "navigator_host_impl.h",
  ]

  if (is_android) {
    sources += [
      "android/android_ui.cc",
      "android/android_ui.h",
    ]
  } else {
    sources += [
      "desktop/desktop_ui.cc",
      "desktop/desktop_ui.h",
    ]
  }

  deps = [
    ":interfaces",
    "//base",
    "//components/view_manager/public/cpp",
    "//mandoline/services/navigation/public/interfaces",
    "//mandoline/tab",
    "//mojo/application/public/interfaces",
    "//mojo/converters/geometry",
    "//skia",
    "//third_party/mojo/src/mojo/public/cpp/bindings",
    "//ui/gfx/geometry",
    "//ui/mojo/events:interfaces",
  ]

  if (!is_android) {
    deps += [ "//mandoline/ui/aura" ]
  }
}

mojom("interfaces") {
  sources = [
    "omnibox.mojom",
    "view_embedder.mojom",
  ]

  import_dirs = [ "//mojo/services" ]

  deps = [
    "//mojo/application/public/interfaces",
    "//mojo/services/network/public/interfaces",
  ]
}