# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")
import("//mojo/public/mojo_application.gni")
import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")

mojo_native_application("browser") {
  sources = [
    "main.cc",
  ]

  deps = [
    ":lib",
    "//mandoline/ui/common/resources",
    "//mojo/application/public/cpp",
  ]

  resources = [ "$root_out_dir/mandoline_ui.pak" ]
}

source_set("lib") {
  sources = [
    "browser_manager.cc",
    "browser_manager.h",
  ]

  deps = [
    "public/interfaces",
    "//base",
    "//mandoline/tab/public/cpp",
    "//mandoline/tab/public/interfaces",
    "//mojo/application/public/cpp:sources",
    "//mojo/common:common_base",
    "//mojo/converters/geometry",
    "//mojo/services/tracing/public/cpp",
    "//mojo/services/tracing/public/interfaces",
    "//skia",
    "//third_party/mojo/src/mojo/public/cpp/bindings",
    "//ui/gfx/geometry",
    "//ui/mojo/events:interfaces",
    "//url",
  ]

  if (is_mac || use_aura) {
    sources += [
      "desktop/desktop_ui.cc",
      "desktop/desktop_ui.h",
    ]
    deps += [
      "//mandoline/ui/aura",
      "//ui/gfx",
      "//ui/views",
    ]
  }
}

mojo_native_application("mandoline_browser_apptests") {
  testonly = true

  sources = [
    "browser_apptest.cc",
  ]

  deps = [
    "//base",
    "//base/test:test_config",
    "//components/view_manager/public/cpp",
    "//mandoline/ui/browser:lib",
    "//mojo/application/public/cpp:sources",
    "//mojo/application/public/cpp:test_support",
  ]
}