O3D: Convolution Shader Sample

This sample shows how to do 2D image processing using render targets. This sample uses a convolution shader to do a 2D Gaussian blur, but the same code could be used for any separable convolution kernel.

float4x4 worldViewProjection : WorldViewProjection;
sampler2D image;
float kernel[KERNEL_WIDTH];
float2 imageIncrement;

struct VertexShaderInput {
  float4 position : POSITION;
  float2 imageCoord : TEXCOORD0;
};

struct PixelShaderInput {
  float4 position : POSITION;
  float2 imageCoord : TEXCOORD0;
};

PixelShaderInput ConvolutionVS(VertexShaderInput input) {
  PixelShaderInput output;
  output.position = mul(input.position, worldViewProjection);

// Offset image coords by half of kernel width, in image texels
  output.imageCoord = input.imageCoord -
    ((KERNEL_WIDTH - 1) / 2) * imageIncrement;

return output;
}

float4 ConvolutionPS(PixelShaderInput input) : COLOR {
  float2 imageCoord = input.imageCoord;
  float4 sum = float4(0.0, 0.0, 0.0, 0.0);
  for (int i = 0; i < KERNEL_WIDTH; ++i) {
    sum += tex2D(image, imageCoord) * kernel[i];
    imageCoord += imageIncrement;
  }
  return sum;
}

// #o3d VertexShaderEntryPoint ConvolutionVS
// #o3d PixelShaderEntryPoint ConvolutionPS
// #o3d MatrixLoadOrder RowMajor

Convolution Shader Example