# Copyright (c) 2006-2008 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.


__doc__ = """
Configuration for building libpng.lib / libpng.a.
"""

Import('env')

if env.WantSystemLib('libpng'):
  Return()

env = env.Clone()

env.ApplySConscript([
    '$ZLIB_DIR/using_zlib.scons',
])

env.Prepend(
    CPPPATH = [
        '$CHROME_SRC_DIR',
    ],
)

if env.Bit('windows'):
  env.Append(
      CCFLAGS = [
          '/TP',
          '/wd4800',
      ],
  )

env.Append(
    CPPDEFINES = [
        'PNG_USER_CONFIG',
        'CHROME_PNG_WRITE_SUPPORT',
    ],
)

input_files = ChromeFileList([
    'png.c',
    'png.h',
    'pngconf.h',
    'pngerror.c',
    'pnggccrd.c',
    'pngget.c',
    'pngmem.c',
    'pngpread.c',
    'pngread.c',
    'pngrio.c',
    'pngrtran.c',
    'pngrutil.c',
    'pngset.c',
    'pngtrans.c',
    'pngusr.h',
    'pngvcrd.c',
    'pngwio.c',
    'pngwrite.c',
    'pngwtran.c',
    'pngwutil.c',
])

env.ChromeLibrary('libpng', input_files)

p = env.ChromeMSVSProject('libpng.vcproj',
                          dest=('$CHROME_SRC_DIR/third_party/'
                                + 'libpng/libpng.vcproj'),
                          guid='{C564F145-9172-42C3-BFCB-6014CA97DBCD}',
                          keyword='Win32Proj',
                          files=input_files,
                          relative_path_prefix='./',
                          tools = [
                              'VCLibrarianTool',
                              'VCCLCompilerTool',
                          ])

p.AddConfig('Debug|Win32',
            ConfigurationType = '4',
            InheritedPropertySheets = [
                '$(SolutionDir)../build/common.vsprops',
                '$(SolutionDir)../build/debug.vsprops',
                '$(SolutionDir)../third_party/zlib/using_zlib.vsprops',
                '$(SolutionDir)../build/external_code.vsprops',
                '$(SolutionDir)../third_party/libpng/using_libpng.vsprops',
            ])

p.AddConfig('Release|Win32',
            ConfigurationType = '4',
            InheritedPropertySheets = [
                '$(SolutionDir)../build/common.vsprops',
                '$(SolutionDir)../build/release.vsprops',
                '$(SolutionDir)../third_party/zlib/using_zlib.vsprops',
                '$(SolutionDir)../build/external_code.vsprops',
                '$(SolutionDir)../third_party/libpng/using_libpng.vsprops',
            ])