blob: 4c52fe179a36c9783c21f566d895b9c0c8d0ffd9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
// Copyright (c) 2009 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#include "chrome/browser/browser_theme_provider.h"
#import <Cocoa/Cocoa.h>
#include "base/logging.h"
#include "skia/ext/skia_utils_mac.h"
NSImage* BrowserThemeProvider::GetNSImageNamed(int id) {
DCHECK(CalledOnValidThread());
if (!HasCustomImage(id))
return nil;
// Check to see if we already have the image in the cache.
NSImageMap::const_iterator found = nsimage_cache_.find(id);
if (found != nsimage_cache_.end())
return found->second;
// Why don't we load the file directly into the image instead of the whole
// SkBitmap > native conversion?
// - For consistency with other platforms.
// - To get the generated tinted images.
SkBitmap* bitmap = GetBitmapNamed(id);
NSImage* nsimage = gfx::SkBitmapToNSImage(*bitmap);
// We loaded successfully. Cache the image.
if (nsimage) {
nsimage_cache_[id] = [nsimage retain];
return nsimage;
}
// We failed to retrieve the bitmap, show a debugging red square.
LOG(WARNING) << "Unable to load NSImage with id " << id;
NOTREACHED(); // Want to assert in debug mode.
static NSImage* empty_image = NULL;
if (!empty_image) {
// The placeholder image is bright red so people notice the problem. This
// image will be leaked, but this code should never be hit.
NSRect image_rect = NSMakeRect(0, 0, 32, 32);
empty_image = [[NSImage alloc] initWithSize:image_rect.size];
[empty_image lockFocus];
[[NSColor redColor] set];
NSRectFill(image_rect);
[empty_image unlockFocus];
}
return empty_image;
}
void BrowserThemeProvider::FreePlatformImages() {
DCHECK(CalledOnValidThread());
// Free images.
for (NSImageMap::iterator i = nsimage_cache_.begin();
i != nsimage_cache_.end(); i++) {
[i->second release];
}
nsimage_cache_.clear();
}
|
