1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
|
// Copyright (c) 2010 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#import "chrome/browser/cocoa/extensions/browser_action_button.h"
#include "app/gfx/canvas_paint.h"
#include "base/gfx/rect.h"
#include "base/gfx/size.h"
#include "base/sys_string_conversions.h"
#include "chrome/browser/cocoa/extensions/extension_action_context_menu.h"
#include "chrome/browser/extensions/image_loading_tracker.h"
#include "chrome/common/extensions/extension.h"
#include "chrome/common/notification_observer.h"
#include "chrome/common/notification_registrar.h"
#include "chrome/common/notification_source.h"
#include "chrome/common/notification_type.h"
#include "skia/ext/skia_utils_mac.h"
static const CGFloat kBrowserActionBadgeOriginYOffset = 5;
// Since the container is the maximum height of the toolbar, we have to move the
// buttons up by this amount in order to have them look vertically centered
// within the toolbar.
static const CGFloat kBrowserActionOriginYOffset = 5;
// The size of each button on the toolbar.
static const CGFloat kBrowserActionHeight = 27;
extern const CGFloat kBrowserActionWidth = 29;
// A helper class to bridge the asynchronous Skia bitmap loading mechanism to
// the extension's button.
class ExtensionImageTrackerBridge : public NotificationObserver,
public ImageLoadingTracker::Observer {
public:
ExtensionImageTrackerBridge(BrowserActionButton* owner, Extension* extension)
: owner_(owner),
tracker_(NULL) {
// The Browser Action API does not allow the default icon path to be
// changed at runtime, so we can load this now and cache it.
std::string path = extension->browser_action()->default_icon_path();
if (!path.empty()) {
tracker_ = new ImageLoadingTracker(this, 1);
tracker_->PostLoadImageTask(extension->GetResource(path),
gfx::Size(Extension::kBrowserActionIconMaxSize,
Extension::kBrowserActionIconMaxSize));
}
registrar_.Add(this, NotificationType::EXTENSION_BROWSER_ACTION_UPDATED,
Source<ExtensionAction>(extension->browser_action()));
}
~ExtensionImageTrackerBridge() {
if (tracker_)
tracker_->StopTrackingImageLoad();
}
// ImageLoadingTracker::Observer implementation.
void OnImageLoaded(SkBitmap* image, size_t index) {
if (image)
[owner_ setDefaultIcon:gfx::SkBitmapToNSImage(*image)];
tracker_ = NULL;
[owner_ updateState];
}
// Overridden from NotificationObserver.
void Observe(NotificationType type,
const NotificationSource& source,
const NotificationDetails& details) {
if (type == NotificationType::EXTENSION_BROWSER_ACTION_UPDATED)
[owner_ updateState];
else
NOTREACHED();
}
private:
// Weak. Owns us.
BrowserActionButton* owner_;
// Loads the button's icons for us on the file thread. Weak.
ImageLoadingTracker* tracker_;
// Used for registering to receive notifications and automatic clean up.
NotificationRegistrar registrar_;
DISALLOW_COPY_AND_ASSIGN(ExtensionImageTrackerBridge);
};
@implementation BrowserActionButton
+ (Class)cellClass {
return [BrowserActionCell class];
}
- (id)initWithExtension:(Extension*)extension
profile:(Profile*)profile
tabId:(int)tabId {
NSRect frame = NSMakeRect(0.0,
kBrowserActionOriginYOffset,
kBrowserActionWidth,
kBrowserActionHeight);
if ((self = [super initWithFrame:frame])) {
BrowserActionCell* cell = [[[BrowserActionCell alloc] init] autorelease];
// [NSButton setCell:] warns to NOT use setCell: other than in the
// initializer of a control. However, we are using a basic
// NSButton whose initializer does not take an NSCell as an
// object. To honor the assumed semantics, we do nothing with
// NSButton between alloc/init and setCell:.
[self setCell:cell];
[cell setTabId:tabId];
[cell setExtensionAction:extension->browser_action()];
[self setTitle:@""];
[self setButtonType:NSMomentaryChangeButton];
[self setShowsBorderOnlyWhileMouseInside:YES];
[self setMenu:[[[ExtensionActionContextMenu alloc]
initWithExtension:extension profile:profile] autorelease]];
tabId_ = tabId;
extension_ = extension;
imageLoadingBridge_.reset(new ExtensionImageTrackerBridge(self, extension));
[self updateState];
}
return self;
}
- (void)setDefaultIcon:(NSImage*)image {
defaultIcon_.reset([image retain]);
}
- (void)setTabSpecificIcon:(NSImage*)image {
tabSpecificIcon_.reset([image retain]);
}
- (void)updateState {
if (tabId_ < 0)
return;
std::string tooltip = extension_->browser_action()->GetTitle(tabId_);
if (tooltip.empty()) {
[self setToolTip:nil];
} else {
[self setToolTip:base::SysUTF8ToNSString(tooltip)];
}
SkBitmap image = extension_->browser_action()->GetIcon(tabId_);
if (!image.isNull()) {
[self setTabSpecificIcon:gfx::SkBitmapToNSImage(image)];
[self setImage:tabSpecificIcon_];
} else if (defaultIcon_) {
[self setImage:defaultIcon_];
}
[[self cell] setTabId:tabId_];
[self setNeedsDisplay:YES];
}
@synthesize tabId = tabId_;
@synthesize extension = extension_;
@end
@implementation BrowserActionCell
- (void)drawInteriorWithFrame:(NSRect)cellFrame inView:(NSView*)controlView {
[NSGraphicsContext saveGraphicsState];
// Create the shadow below and to the right of the drawn image.
scoped_nsobject<NSShadow> imgShadow([[NSShadow alloc] init]);
[imgShadow setShadowOffset:NSMakeSize(2.0, -2.0)];
[imgShadow setShadowBlurRadius:2.0];
[imgShadow setShadowColor:[[NSColor blackColor] colorWithAlphaComponent:0.3]];
[imgShadow set];
[super drawInteriorWithFrame:cellFrame inView:controlView];
// CanvasPaint draws its content to the current NSGraphicsContext in its
// destructor, so it is enclosed in a nested block.
{
cellFrame.origin.y += kBrowserActionBadgeOriginYOffset;
gfx::CanvasPaint canvas(cellFrame, false);
canvas.set_composite_alpha(true);
gfx::Rect boundingRect(NSRectToCGRect(cellFrame));
extensionAction_->PaintBadge(&canvas, boundingRect, tabId_);
}
[NSGraphicsContext restoreGraphicsState];
}
@synthesize tabId = tabId_;
@synthesize extensionAction = extensionAction_;
@end
|
