1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
|
// Copyright (c) 2011 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#include "chrome/browser/ui/cocoa/keystone_infobar.h"
#import <AppKit/AppKit.h>
#include <string>
#include "base/command_line.h"
#include "base/message_loop.h"
#include "base/task.h"
#include "chrome/browser/first_run/first_run.h"
#include "chrome/browser/prefs/pref_service.h"
#include "chrome/browser/profiles/profile.h"
#include "chrome/browser/tab_contents/infobar_delegate.h"
#include "chrome/browser/tab_contents/navigation_controller.h"
#include "chrome/browser/tab_contents/tab_contents.h"
#include "chrome/browser/ui/browser.h"
#include "chrome/browser/ui/browser_list.h"
#import "chrome/browser/ui/cocoa/keystone_glue.h"
#include "chrome/common/chrome_switches.h"
#include "chrome/common/pref_names.h"
#include "grit/chromium_strings.h"
#include "grit/generated_resources.h"
#include "grit/theme_resources.h"
#include "ui/base/l10n/l10n_util.h"
#include "ui/base/resource/resource_bundle.h"
class SkBitmap;
namespace {
// KeystonePromotionInfoBarDelegate -------------------------------------------
class KeystonePromotionInfoBarDelegate : public ConfirmInfoBarDelegate {
public:
explicit KeystonePromotionInfoBarDelegate(TabContents* tab_contents);
private:
virtual ~KeystonePromotionInfoBarDelegate();
// Sets this info bar to be able to expire. Called a predetermined amount
// of time after this object is created.
void SetCanExpire() { can_expire_ = true; }
// ConfirmInfoBarDelegate
virtual bool ShouldExpire(
const NavigationController::LoadCommittedDetails& details) const;
virtual void InfoBarClosed();
virtual SkBitmap* GetIcon() const;
virtual string16 GetMessageText() const;
virtual string16 GetButtonLabel(InfoBarButton button) const;
virtual bool Accept();
virtual bool Cancel();
// The TabContents' profile.
Profile* profile_; // weak
// Whether the info bar should be dismissed on the next navigation.
bool can_expire_;
// Used to delay the expiration of the info bar.
ScopedRunnableMethodFactory<KeystonePromotionInfoBarDelegate> method_factory_;
DISALLOW_COPY_AND_ASSIGN(KeystonePromotionInfoBarDelegate);
};
KeystonePromotionInfoBarDelegate::KeystonePromotionInfoBarDelegate(
TabContents* tab_contents)
: ConfirmInfoBarDelegate(tab_contents),
profile_(tab_contents->profile()),
can_expire_(false),
ALLOW_THIS_IN_INITIALIZER_LIST(method_factory_(this)) {
const int kCanExpireOnNavigationAfterMilliseconds = 8 * 1000;
MessageLoop::current()->PostDelayedTask(FROM_HERE,
method_factory_.NewRunnableMethod(
&KeystonePromotionInfoBarDelegate::SetCanExpire),
kCanExpireOnNavigationAfterMilliseconds);
}
KeystonePromotionInfoBarDelegate::~KeystonePromotionInfoBarDelegate() {
}
bool KeystonePromotionInfoBarDelegate::ShouldExpire(
const NavigationController::LoadCommittedDetails& details) const {
return can_expire_;
}
void KeystonePromotionInfoBarDelegate::InfoBarClosed() {
delete this;
}
SkBitmap* KeystonePromotionInfoBarDelegate::GetIcon() const {
return ResourceBundle::GetSharedInstance().GetBitmapNamed(
IDR_PRODUCT_ICON_32);
}
string16 KeystonePromotionInfoBarDelegate::GetMessageText() const {
return l10n_util::GetStringFUTF16(IDS_PROMOTE_INFOBAR_TEXT,
l10n_util::GetStringUTF16(IDS_PRODUCT_NAME));
}
string16 KeystonePromotionInfoBarDelegate::GetButtonLabel(
InfoBarButton button) const {
return l10n_util::GetStringUTF16((button == BUTTON_OK) ?
IDS_PROMOTE_INFOBAR_PROMOTE_BUTTON : IDS_PROMOTE_INFOBAR_DONT_ASK_BUTTON);
}
bool KeystonePromotionInfoBarDelegate::Accept() {
[[KeystoneGlue defaultKeystoneGlue] promoteTicket];
return true;
}
bool KeystonePromotionInfoBarDelegate::Cancel() {
profile_->GetPrefs()->SetBoolean(prefs::kShowUpdatePromotionInfoBar, false);
return true;
}
} // namespace
// KeystonePromotionInfoBar ---------------------------------------------------
@interface KeystonePromotionInfoBar : NSObject
- (void)checkAndShowInfoBarForProfile:(Profile*)profile;
- (void)updateStatus:(NSNotification*)notification;
- (void)removeObserver;
@end // @interface KeystonePromotionInfoBar
@implementation KeystonePromotionInfoBar
- (void)dealloc {
[self removeObserver];
[super dealloc];
}
- (void)checkAndShowInfoBarForProfile:(Profile*)profile {
// If this is the first run, the user clicked the "don't ask again" button
// at some point in the past, or if the "don't ask about the default
// browser" command-line switch is present, bail out. That command-line
// switch is recycled here because it's likely that the set of users that
// don't want to be nagged about the default browser also don't want to be
// nagged about the update check. (Automated testers, I'm thinking of
// you...)
CommandLine* commandLine = CommandLine::ForCurrentProcess();
if (FirstRun::IsChromeFirstRun() ||
!profile->GetPrefs()->GetBoolean(prefs::kShowUpdatePromotionInfoBar) ||
commandLine->HasSwitch(switches::kNoDefaultBrowserCheck)) {
return;
}
// If there is no Keystone glue (maybe because this application isn't
// Keystone-enabled) or the application is on a read-only filesystem,
// doing anything related to auto-update is pointless. Bail out.
KeystoneGlue* keystoneGlue = [KeystoneGlue defaultKeystoneGlue];
if (!keystoneGlue || [keystoneGlue isOnReadOnlyFilesystem]) {
return;
}
// Stay alive as long as needed. This is balanced by a release in
// -updateStatus:.
[self retain];
AutoupdateStatus recentStatus = [keystoneGlue recentStatus];
if (recentStatus == kAutoupdateNone ||
recentStatus == kAutoupdateRegistering) {
NSNotificationCenter* center = [NSNotificationCenter defaultCenter];
[center addObserver:self
selector:@selector(updateStatus:)
name:kAutoupdateStatusNotification
object:nil];
} else {
[self updateStatus:[keystoneGlue recentNotification]];
}
}
- (void)updateStatus:(NSNotification*)notification {
NSDictionary* dictionary = [notification userInfo];
AutoupdateStatus status = static_cast<AutoupdateStatus>(
[[dictionary objectForKey:kAutoupdateStatusStatus] intValue]);
if (status == kAutoupdateNone || status == kAutoupdateRegistering) {
return;
}
[self removeObserver];
if (status != kAutoupdateRegisterFailed &&
[[KeystoneGlue defaultKeystoneGlue] needsPromotion]) {
Browser* browser = BrowserList::GetLastActive();
if (browser) {
TabContents* tabContents = browser->GetSelectedTabContents();
// Only show if no other info bars are showing, because that's how the
// default browser info bar works.
if (tabContents && tabContents->infobar_delegate_count() == 0) {
tabContents->AddInfoBar(
new KeystonePromotionInfoBarDelegate(tabContents));
}
}
}
[self release];
}
- (void)removeObserver {
[[NSNotificationCenter defaultCenter] removeObserver:self];
}
@end // @implementation KeystonePromotionInfoBar
// static
void KeystoneInfoBar::PromotionInfoBar(Profile* profile) {
KeystonePromotionInfoBar* promotionInfoBar =
[[[KeystonePromotionInfoBar alloc] init] autorelease];
[promotionInfoBar checkAndShowInfoBarForProfile:profile];
}
|
