third_party/adobe/flash/BUILD.gn


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

if (is_chrome_branded) {
  if (is_linux && cpu_arch == "x86") {
    flapper_version_h_file = "symbols/ppapi/linux/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/linux/libpepflashplayer.so",
      "binaries/ppapi/linux/manifest.json",
    ]
  } else if (is_linux && cpu_arch == "x64") {
    flapper_version_h_file = "symbols/ppapi/linux_x64/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/linux_x64/libpepflashplayer.so",
      "binaries/ppapi/linux_x64/manifest.json",
    ]
  } else if (is_mac && cpu_arch == "x86") {
    flapper_version_h_file = "symbols/ppapi/mac/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/mac/PepperFlashPlayer.plugin",
      "binaries/ppapi/mac/manifest.json",
    ]
  } else if (is_mac && cpu_arch == "x64") {
    flapper_version_h_file = "symbols/ppapi/mac_64/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/mac_64/PepperFlashPlayer.plugin",
      "binaries/ppapi/mac_64/manifest.json",
    ]
  } else if (is_win && cpu_arch == "x86") {
    flapper_version_h_file = "symbols/ppapi/win/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/win/pepflashplayer.dll",
      "binaries/ppapi/win/manifest.json",
    ]
  } else if (is_win && cpu_arch == "x64") {
    flapper_version_h_file = "symbols/ppapi/win_x64/flapper_version.h"
    flapper_binary_files = [
      "binaries/ppapi/win_x64/pepflashplayer.dll",
      "binaries/ppapi/win_x64/manifest.json",
    ]
  } else {
    flapper_version_h_file = "flapper_version.h"
    flapper_binary_files = []
  }
} else {
  flapper_version_h_file = "flapper_version.h"
  flapper_binary_files = []
}

copy("flapper_version_h") {
  sources = [ flapper_version_h_file ]
  outputs = [ "$root_gen_dir/{{source_file_part}}" ]
}

if (flapper_binary_files == []) {
  group("flapper_binaries") {
    # NOP
  }
} else {
  copy("flapper_binaries") {
    sources = flapper_binary_files
    outputs = [ "$root_out_dir/PepperFlash/{{source_file_part}}" ]
  }
}