Subpackage for formatted output in C++, version 1.0.

1 files changed, 64 insertions, 0 deletions

diff --git a/libasprintf/configure.in b/libasprintf/configure.in
new file mode 100644
index 0000000..ec9e8a4
--- /dev/null
+++ b/libasprintf/configure.in
@@ -0,0 +1,64 @@
+dnl Process this file with autoconf to produce a configure script.
+AC_PREREQ(2.52)
+AC_INIT
+AC_CONFIG_SRCDIR(vasprintf.c)
+AM_INIT_AUTOMAKE(libasprintf, 1.0)
+AM_CONFIG_HEADER(config.h)
+
+dnl Checks for programs.
+AC_PROG_CC
+AC_PROG_CXX
+AC_PROG_INSTALL
+
+dnl Check for host type.
+AC_CANONICAL_HOST
+
+dnl Checks for compiler output filename suffixes.
+AC_OBJEXT
+AC_EXEEXT
+
+dnl Check for build configuration.
+AC_LIBTOOL_WIN32_DLL
+AC_PROG_LIBTOOL
+
+dnl Checks for libraries.
+
+dnl Checks for header files.
+
+dnl Checks for typedefs, structures, and compiler characteristics.
+AC_C_CONST
+bh_C_SIGNED
+AC_TYPE_SIZE_T
+gt_TYPE_LONGLONG
+gt_TYPE_LONGDOUBLE
+gt_TYPE_WCHAR_T
+AC_CHECK_TYPES(ptrdiff_t)
+gt_TYPE_INTMAX_T
+
+dnl Checks for library functions.
+AC_FUNC_ALLOCA
+AC_CHECK_FUNCS([snprintf vasprintf])
+
+dnl Check for tools needed for formatting the documentation.
+ac_aux_dir_abs=`cd $ac_aux_dir && pwd`
+AC_PATH_PROG(DVIPS, dvips, $ac_aux_dir_abs/missing dvips)
+AC_PATH_PROG(TEXI2PDF, texi2pdf, $ac_aux_dir_abs/missing texi2pdf)
+AC_PATH_PROG(PERL, perl, $ac_aux_dir_abs/missing perl)
+
+AC_OUTPUT([Makefile], [
+  dnl Fix unesthetic build commands generated by automake.
+  for m in Makefile; do
+    sed -e "s,\`test -f \\\$< || echo '\\\$(srcdir)/'\`\\\$<,\\\$<," < $m > $m.tmp
+    mv $m.tmp $m
+  done
+  dnl Fix an automake-1.5 bug.
+  for m in Makefile; do
+    sed -e 's,^#distdir:,distdir:,' < $m > $m.tmp
+    mv $m.tmp $m
+  done
+  dnl Fix an automake-1.5 bug: all info files are erased by "make".
+  for m in Makefile; do
+    sed -e '/cd \$(srcdir) && rm -f /d' < $m > $m.tmp
+    mv $m.tmp $m
+  done
+])