dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.12)
AC_REVISION($Revision: 1.4 $)
AC_INIT(src/msgfmt.c)
AM_INIT_AUTOMAKE(gettext, 0.10.36)
AM_CONFIG_HEADER(config.h)

dnl Set of available languages.
ALL_LINGUAS="da de el es fr ko nl no no@nynorsk pl pt sl sv tr"

dnl Checks for programs.
AC_PROG_CC
AM_PROG_LIBTOOL
AC_ISC_POSIX
AC_PROG_INSTALL
AC_PROG_YACC

dnl Make sure we see all GNU extensions.
AC_DEFINE(_GNU_SOURCE)

dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC
AC_HAVE_HEADERS(limits.h malloc.h string.h unistd.h values.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_C_BACKSLASH_A
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AM_TYPE_PTRDIFF_T

dnl Checks for library functions.
AC_FUNC_ALLOCA
AC_FUNC_VPRINTF
AC_CHECK_FUNCS([getcwd mblen memcpy strchr strerror uname])
AC_REPLACE_FUNCS([getline memmove memset stpcpy stpncpy strcspn \
strncasecmp strstr strtoul vasprintf])
if test $ac_cv_func_getline != yes; then
  AC_CHECK_FUNCS(getdelim)
fi

AC_CHECK_FUNC(parse_printf_format, gt_cv_func_parse_printf_format=yes,
  gt_cv_func_parse_printf_format=no)
if test $gt_cv_func_parse_printf_format = yes; then
  AC_DEFINE(HAVE_PARSE_PRINTF_FORMAT)
else
  LIBOBJS="$LIBOBJS printf-prs.o"
fi

AM_FUNC_ERROR_AT_LINE

dnl These are the only lines required to internationalize the package.
dnl (OK, not quite, the AC_OUTPUT has also some parts.)
AM_GNU_GETTEXT

dnl Check for Emacs and where to install .elc files.
AM_PATH_LISPDIR

dnl The gettextize script test for the version of the aclocal.m4 file in
dnl user's project.  This must correspond to the number the aclocal.m4
dnl here has.  Extract it.
changequote(,)dnl
ACLOCAL_VERSION=`sed -e 's/.*Last updated for gettext-\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\).*/\1/p' -e d $srcdir/aclocal.m4`
changequote([, ])dnl
AC_SUBST(ACLOCAL_VERSION)

aclocaldir='${datadir}/aclocal'
AC_SUBST(aclocaldir)


dnl Generate the version information file in the intl/ directory.
test -d intl || mkdir intl
echo "GNU gettext library from $PACKAGE-$VERSION" > intl/VERSION

AC_OUTPUT([Makefile lib/Makefile intl/Makefile src/Makefile \
           po/Makefile.in doc/Makefile tests/Makefile m4/Makefile \
	   misc/Makefile misc/gettextize intl/intlh.inst], [
  dnl Workaround an automake-1.4 bug which generates an incorrect uninstall
  dnl target in misc/Makefile.in.
  sed -e 's/rm -f \$(lispdir)/rm -f \$(DESTDIR)\$(lispdir)/' < misc/Makefile \
      > misc/Makefile.tmp
  mv misc/Makefile.tmp misc/Makefile
])