GN build: GPU work, Windows compile, "check" errors

Fix the "gn check" header errors.

Remove the extra "gles2_utils" target which "gn check" flags as an error. This target is actually inseparable from "command_buffer_common" but exists this way to prevent cycles in GYP files (but not GYP targets). GN doesn't have this problem, so I merged them.

Moved the GPU targets out into build files closer to their files (gpu/command_buffer/client and .../common). This leaves a BUILD.gn file in gpu/ with a comment listing the forwarding locations, since that's where people will look for a BUILD.gn file first.

Delete the duplicate gfx_unittests target, leave a comment for where it is in case somebody does a search for that name.

Make webp compile on Windows

Make ui/gfx compile on Windows. There were some duplicate symbols for ozone. I changed some of the filtering around to do += instead of exclusion. I think in these cases it's easier to follow and maintain.

BUG=
R=piman@chromium.org, urvang@google.com

Review URL: https://codereview.chromium.org/288033016

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@271080 0039d316-1c4b-4281-b951-d872f2087c98

11 files changed, 206 insertions, 254 deletions

diff --git a/BUILD.gn b/BUILD.gn
index 15d7fd2..e0e0207 100644
--- a/BUILD.gn
+++ b/BUILD.gn
@@ -32,7 +32,7 @@ group("root") {
     "//crypto",
     "//device/usb",
     #"//extensions/common/api:extensions_api",
-    "//gpu:gles2_c_lib",
+    "//gpu/command_buffer/client",
     "//ipc",
     "//mojo",
     "//net",
@@ -75,7 +75,7 @@ group("root") {
     deps -= [
       "//components/os_crypt",
       "//crypto",
-      "//gpu:gles2_c_lib",  # Needs Skia.
+      "//gpu/command_buffer/client",  # Needs Skia.
       "//net",
       "//skia",  # Needs some ARM stuff
       "//third_party/libusb",
diff --git a/gpu/BUILD.gn b/gpu/BUILD.gn
index 4e2d47a..bb0baf2 100644
--- a/gpu/BUILD.gn
+++ b/gpu/BUILD.gn
@@ -2,144 +2,20 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-config("sizet_truncations") {
-  if (is_win) {
-    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
-    cflags = [ "/wd4267" ]  # size_t to int truncation.
-  }
-}
-
-gles2_c_lib_source_files = [
-  "command_buffer/client/gles2_c_lib.cc",
-  "command_buffer/client/gles2_c_lib_autogen.h",
-  "command_buffer/client/gles2_c_lib_export.h",
-  "command_buffer/client/gles2_lib.h",
-  "command_buffer/client/gles2_lib.cc",
-]
-
-component("gles2_implementation") {
-  sources = [
-    "command_buffer/client/buffer_tracker.cc",
-    "command_buffer/client/buffer_tracker.h",
-    "command_buffer/client/client_context_state.h",
-    "command_buffer/client/client_context_state.cc",
-    "command_buffer/client/client_context_state_autogen.h",
-    "command_buffer/client/client_context_state_impl_autogen.h",
-    "command_buffer/client/gles2_impl_export.h",
-    "command_buffer/client/gles2_implementation_autogen.h",
-    "command_buffer/client/gles2_implementation.cc",
-    "command_buffer/client/gles2_implementation.h",
-    "command_buffer/client/gles2_implementation_impl_autogen.h",
-    "command_buffer/client/gles2_interface.h",
-    "command_buffer/client/gles2_trace_implementation_autogen.h",
-    "command_buffer/client/gles2_trace_implementation.cc",
-    "command_buffer/client/gles2_trace_implementation.h",
-    "command_buffer/client/gles2_trace_implementation_impl_autogen.h",
-    "command_buffer/client/gpu_memory_buffer_factory.h",
-    "command_buffer/client/gpu_memory_buffer_tracker.cc",
-    "command_buffer/client/gpu_memory_buffer_tracker.h",
-    "command_buffer/client/program_info_manager.cc",
-    "command_buffer/client/program_info_manager.h",
-    "command_buffer/client/query_tracker.cc",
-    "command_buffer/client/query_tracker.h",
-    "command_buffer/client/share_group.cc",
-    "command_buffer/client/share_group.h",
-    "command_buffer/client/vertex_array_object_manager.cc",
-    "command_buffer/client/vertex_array_object_manager.h",
-  ]
-  defines = [ "GLES2_IMPL_IMPLEMENTATION" ]
-  configs += [ ":sizet_truncations" ]
-  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
-
-  deps = [
-    ":gles2_cmd_helper",
-    "//base",
-    "//gpu/command_buffer:gles2_utils",
-    "//ui/gfx/geometry",
-    "//ui/gl",
-  ]
-}
-
-component("gles2_c_lib") {
-  sources = gles2_c_lib_source_files
-  defines = [ "GLES2_C_LIB_IMPLEMENTATION" ]
-  configs += [ ":sizet_truncations" ]
-
-  deps = [
-    ":command_buffer_client",
-    ":gles2_implementation",
-    "//base",
-    "//base/third_party/dynamic_annotations",
-    "//gpu/command_buffer:gles2_utils",
-  ]
-}
-
-source_set("gles2_cmd_helper") {
-  sources = [
-    "command_buffer/client/gles2_cmd_helper.cc",
-    "command_buffer/client/gles2_cmd_helper.h",
-    "command_buffer/client/gles2_cmd_helper_autogen.h",
-  ]
-
-  configs += [ ":sizet_truncations" ]
-  deps = [ ":command_buffer_client" ]
-}
-
-source_set("command_buffer_client") {
-  sources = [
-    "command_buffer/client/cmd_buffer_helper.cc",
-    "command_buffer/client/cmd_buffer_helper.h",
-    "command_buffer/client/fenced_allocator.cc",
-    "command_buffer/client/fenced_allocator.h",
-    "command_buffer/client/gpu_control.h",
-    "command_buffer/client/mapped_memory.cc",
-    "command_buffer/client/mapped_memory.h",
-    "command_buffer/client/ring_buffer.cc",
-    "command_buffer/client/ring_buffer.h",
-    "command_buffer/client/transfer_buffer.cc",
-    "command_buffer/client/transfer_buffer.h",
-  ]
-
-  configs += [ ":sizet_truncations" ]
-  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
-
-  deps = [
-    ":command_buffer_common",
-  ]
-}
-
-source_set("command_buffer_common") {
-  sources = [
-    "command_buffer/common/bitfield_helpers.h",
-    "command_buffer/common/buffer.cc",
-    "command_buffer/common/buffer.h",
-    "command_buffer/common/capabilities.cc",
-    "command_buffer/common/capabilities.h",
-    "command_buffer/common/cmd_buffer_common.cc",
-    "command_buffer/common/cmd_buffer_common.h",
-    "command_buffer/common/command_buffer.h",
-    "command_buffer/common/constants.h",
-    "command_buffer/common/debug_marker_manager.cc",
-    "command_buffer/common/debug_marker_manager.h",
-    "command_buffer/common/gles2_cmd_format.cc",
-    "command_buffer/common/gles2_cmd_format.h",
-    "command_buffer/common/gles2_cmd_format_autogen.h",
-    "command_buffer/common/gles2_cmd_ids.h",
-    "command_buffer/common/gles2_cmd_ids_autogen.h",
-    "command_buffer/common/id_allocator.cc",
-    "command_buffer/common/id_allocator.h",
-    "command_buffer/common/mailbox.cc",
-    "command_buffer/common/mailbox.h",
-    "command_buffer/common/mailbox_holder.cc",
-    "command_buffer/common/mailbox_holder.h",
-    "command_buffer/common/thread_local.h",
-    "command_buffer/common/time.h",
-  ]
-
-  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
-
-  deps = [
-    "//base",
-    "//gpu/command_buffer:gles2_utils",
-  ]
-}
+# GYP-to-GN project mappings:
+#
+#  gpu.gyp:command_buffer_client => //gpu/command_buffer/client
+#
+#  gpu.gyp:command_buffer_common => //gpu/command_buffer/common
+#
+#  gpu.gyp:gles2_cmd_helper => //gpu/command_buffer/client:gles2_cmd_helper
+#
+#  gpu.gyp:gles2_c_lib => //gpu/command_buffer/client:cles2_c_lib
+#
+#  gpu.gyp:gles2_implementation =>
+#      //gpu_command_buffer/client:gles2_implementation
+#
+#  command_buffer/command_buffer.gyp:gles2_utils =>
+#     //gpu/command_buffer/common
+#     (Merged in to here because the separate file exists in GYP only to break
+#     a .gyp file dependency cycle which GN doesn't have.)
diff --git a/gpu/command_buffer/BUILD.gn b/gpu/command_buffer/BUILD.gn
deleted file mode 100644
index c37e90f..0000000
--- a/gpu/command_buffer/BUILD.gn
+++ /dev/null
@@ -1,17 +0,0 @@
-# Copyright 2014 The Chromium Authors. All rights reserved.
-# Use of this source code is governed by a BSD-style license that can be
-# found in the LICENSE file.
-
-component("gles2_utils") {
-  sources = [
-    "common/gles2_cmd_format.h",
-    "common/gles2_cmd_utils.cc",
-    "common/gles2_cmd_utils.h",
-    "common/gles2_utils_export.h",
-  ]
-
-  defines = [ "GLES2_UTILS_IMPLEMENTATION" ]
-  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
-  deps = [ "//base" ]
-}
-
diff --git a/gpu/command_buffer/client/BUILD.gn b/gpu/command_buffer/client/BUILD.gn
new file mode 100644
index 0000000..910af3c
--- /dev/null
+++ b/gpu/command_buffer/client/BUILD.gn
@@ -0,0 +1,119 @@
+# Copyright (c) 2013 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("client") {
+  sources = [
+    "cmd_buffer_helper.cc",
+    "cmd_buffer_helper.h",
+    "fenced_allocator.cc",
+    "fenced_allocator.h",
+    "gpu_control.h",
+    "mapped_memory.cc",
+    "mapped_memory.h",
+    "ring_buffer.cc",
+    "ring_buffer.h",
+    "transfer_buffer.cc",
+    "transfer_buffer.h",
+  ]
+
+  if (is_win) {
+    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+    cflags = [ "/wd4267" ]  # size_t to int truncation.
+  }
+
+  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
+
+  deps = [
+    "//gpu/command_buffer/common",
+  ]
+}
+
+source_set("gles2_cmd_helper") {
+  sources = [
+    "gles2_cmd_helper.cc",
+    "gles2_cmd_helper.h",
+    "gles2_cmd_helper_autogen.h",
+  ]
+
+  if (is_win) {
+    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+    cflags = [ "/wd4267" ]  # size_t to int truncation.
+  }
+
+  deps = [ ":client" ]
+}
+
+gles2_c_lib_source_files = [
+  "gles2_c_lib.cc",
+  "gles2_c_lib_autogen.h",
+  "gles2_c_lib_export.h",
+  "gles2_lib.h",
+  "gles2_lib.cc",
+]
+
+component("gles2_implementation") {
+  sources = [
+    "buffer_tracker.cc",
+    "buffer_tracker.h",
+    "client_context_state.h",
+    "client_context_state.cc",
+    "client_context_state_autogen.h",
+    "client_context_state_impl_autogen.h",
+    "gles2_impl_export.h",
+    "gles2_implementation_autogen.h",
+    "gles2_implementation.cc",
+    "gles2_implementation.h",
+    "gles2_implementation_impl_autogen.h",
+    "gles2_interface.h",
+    "gles2_trace_implementation_autogen.h",
+    "gles2_trace_implementation.cc",
+    "gles2_trace_implementation.h",
+    "gles2_trace_implementation_impl_autogen.h",
+    "gpu_memory_buffer_factory.h",
+    "gpu_memory_buffer_tracker.cc",
+    "gpu_memory_buffer_tracker.h",
+    "program_info_manager.cc",
+    "program_info_manager.h",
+    "query_tracker.cc",
+    "query_tracker.h",
+    "share_group.cc",
+    "share_group.h",
+    "vertex_array_object_manager.cc",
+    "vertex_array_object_manager.h",
+  ]
+  defines = [ "GLES2_IMPL_IMPLEMENTATION" ]
+  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
+
+  if (is_win) {
+    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+    cflags = [ "/wd4267" ]  # size_t to int truncation.
+  }
+
+  deps = [
+    ":gles2_cmd_helper",
+    "//base",
+    "//gpu/command_buffer/common",
+    "//ui/gfx/geometry",
+    "//ui/gl",
+  ]
+}
+
+component("gles2_c_lib") {
+  sources = gles2_c_lib_source_files
+  defines = [ "GLES2_C_LIB_IMPLEMENTATION" ]
+
+  if (is_win) {
+    # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+    cflags = [ "/wd4267" ]  # size_t to int truncation.
+  }
+
+  deps = [
+    ":client",
+    ":gles2_implementation",
+    "//base",
+    "//base/third_party/dynamic_annotations",
+    "//gpu/command_buffer/common",
+  ]
+}
+
diff --git a/gpu/command_buffer/common/BUILD.gn b/gpu/command_buffer/common/BUILD.gn
new file mode 100644
index 0000000..43b1940
--- /dev/null
+++ b/gpu/command_buffer/common/BUILD.gn
@@ -0,0 +1,42 @@
+# Copyright (c) 2013 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("common") {
+  sources = [
+    "bitfield_helpers.h",
+    "buffer.cc",
+    "buffer.h",
+    "capabilities.cc",
+    "capabilities.h",
+    "cmd_buffer_common.cc",
+    "cmd_buffer_common.h",
+    "command_buffer.h",
+    "constants.h",
+    "debug_marker_manager.cc",
+    "debug_marker_manager.h",
+    "gles2_cmd_format.cc",
+    "gles2_cmd_format.h",
+    "gles2_cmd_format.h",
+    "gles2_cmd_format_autogen.h",
+    "gles2_cmd_ids.h",
+    "gles2_cmd_ids_autogen.h",
+    "gles2_cmd_utils.cc",
+    "gles2_cmd_utils.h",
+    "gles2_utils_export.h",
+    "id_allocator.cc",
+    "id_allocator.h",
+    "mailbox.cc",
+    "mailbox.h",
+    "mailbox_holder.cc",
+    "mailbox_holder.h",
+    "thread_local.h",
+    "time.h",
+  ]
+
+  all_dependent_configs = [ "//third_party/khronos:khronos_headers" ]
+
+  deps = [
+    "//base",
+  ]
+}
diff --git a/gpu/command_buffer/common/gles2_cmd_format.h b/gpu/command_buffer/common/gles2_cmd_format.h
index 79baf97..a541cbb 100644
--- a/gpu/command_buffer/common/gles2_cmd_format.h
+++ b/gpu/command_buffer/common/gles2_cmd_format.h
@@ -14,6 +14,7 @@
 #include <string.h>
 
 #include "base/atomicops.h"
+#include "base/logging.h"
 #include "base/macros.h"
 #include "gpu/command_buffer/common/bitfield_helpers.h"
 #include "gpu/command_buffer/common/cmd_buffer_common.h"
diff --git a/third_party/libwebp/BUILD.gn b/third_party/libwebp/BUILD.gn
index cf7dccd..48e548e 100644
--- a/third_party/libwebp/BUILD.gn
+++ b/third_party/libwebp/BUILD.gn
@@ -20,6 +20,10 @@ source_set("libwebp_dec") {
     "dec/vp8l.c",
     "dec/webp.c",
   ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+
   deps = [
     ":libwebp_dsp",
 # TODO(GYP):
@@ -53,6 +57,9 @@ source_set("libwebp_dsp") {
     "dsp/upsampling_sse2.c",
     "dsp/yuv.c",
   ]
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+
   all_dependent_configs = [
     ":libwebp_config"
   ]
@@ -120,6 +127,9 @@ source_set("libwebp_enc") {
     "enc/vp8l.c",
     "enc/webpenc.c",
   ]
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+
   all_dependent_configs = [
     ":libwebp_config"
   ]
@@ -141,6 +151,9 @@ source_set("libwebp_utils") {
     "utils/thread.c",
     "utils/utils.c",
   ]
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+
   all_dependent_configs = [
     ":libwebp_config"
   ]
diff --git a/ui/base/BUILD.gn b/ui/base/BUILD.gn
index c1d8714..2aa1309 100644
--- a/ui/base/BUILD.gn
+++ b/ui/base/BUILD.gn
@@ -519,6 +519,7 @@ source_set("ui_base_test_support") {
     "//base",
     "//skia",
     "//testing/gtest",
+    "//ui/events:events_base",
     "//ui/gfx",
     "//ui/gfx/geometry",
   ]
diff --git a/ui/gfx/BUILD.gn b/ui/gfx/BUILD.gn
index 4270699..11ba78f 100644
--- a/ui/gfx/BUILD.gn
+++ b/ui/gfx/BUILD.gn
@@ -137,27 +137,6 @@ component("gfx") {
     "native_widget_types.h",
     "nine_image_painter.cc",
     "nine_image_painter.h",
-    "ozone/dri/dri_skbitmap.cc",
-    "ozone/dri/dri_skbitmap.h",
-    "ozone/dri/dri_surface.cc",
-    "ozone/dri/dri_surface.h",
-    "ozone/dri/dri_surface_factory.cc",
-    "ozone/dri/dri_surface_factory.h",
-    "ozone/dri/dri_vsync_provider.cc",
-    "ozone/dri/dri_vsync_provider.h",
-    "ozone/dri/dri_wrapper.cc",
-    "ozone/dri/dri_wrapper.h",
-    "ozone/dri/hardware_display_controller.cc",
-    "ozone/dri/hardware_display_controller.h",
-    "ozone/impl/file_surface_factory.cc",
-    "ozone/impl/file_surface_factory.h",
-    "ozone/surface_factory_ozone.cc",
-    "ozone/surface_factory_ozone.h",
-    "ozone/surface_ozone.h",
-    "ozone/overlay_candidates_ozone.cc",
-    "ozone/overlay_candidates_ozone.h",
-    "pango_util.cc",
-    "pango_util.h",
     "path.cc",
     "path.h",
     "path_aura.cc",
@@ -171,9 +150,6 @@ component("gfx") {
     "platform_font_ios.mm",
     "platform_font_mac.h",
     "platform_font_mac.mm",
-    "platform_font_ozone.cc",
-    "platform_font_pango.cc",
-    "platform_font_pango.h",
     "platform_font_win.cc",
     "platform_font_win.h",
     "range/range.cc",
@@ -184,9 +160,6 @@ component("gfx") {
     "render_text.h",
     "render_text_mac.cc",
     "render_text_mac.h",
-    "render_text_ozone.cc",
-    "render_text_pango.cc",
-    "render_text_pango.h",
     "render_text_win.cc",
     "render_text_win.h",
     "scoped_canvas.h",
@@ -328,8 +301,10 @@ component("gfx") {
   }
 
   # Ozone stuff.
-  if (!use_ozone) {
-    sources -= [
+  if (use_ozone) {
+    sources += [
+      "platform_font_ozone.cc",
+      "render_text_ozone.cc",
       "ozone/impl/file_surface_factory.cc",
       "ozone/impl/file_surface_factory.h",
       "ozone/surface_factory_ozone.cc",
@@ -340,9 +315,7 @@ component("gfx") {
     ]
   }
   if (use_ozone && ozone_platform_dri) {
-    configs += [ "//build/config/linux:dridrm" ]
-  } else {
-    sources -= [
+    sources += [
       "ozone/dri/dri_skbitmap.cc",
       "ozone/dri/dri_skbitmap.h",
       "ozone/dri/dri_surface.cc",
@@ -356,6 +329,7 @@ component("gfx") {
       "ozone/dri/hardware_display_controller.cc",
       "ozone/dri/hardware_display_controller.h",
     ]
+    configs += [ "//build/config/linux:dridrm" ]
   }
 
   if (!use_aura) {
@@ -377,13 +351,7 @@ component("gfx") {
   }
 
   if (use_pango) {
-    sources -= [
-      "platform_font_ozone.cc",
-      "render_text_ozone.cc",
-    ]
-    configs += [ "//build/config/linux:pangocairo" ]
-  } else {
-    sources -= [
+    sources += [
       "pango_util.cc",
       "pango_util.h",
       "platform_font_pango.cc",
@@ -391,63 +359,11 @@ component("gfx") {
       "render_text_pango.cc",
       "render_text_pango.h",
     ]
+    configs += [ "//build/config/linux:pangocairo" ]
   }
 }
 
-component("gfx_geometry") {
-  sources = [
-    "geometry/box_f.cc",
-    "geometry/box_f.h",
-    "geometry/cubic_bezier.h",
-    "geometry/cubic_bezier.cc",
-    "geometry/insets.cc",
-    "geometry/insets.h",
-    "geometry/insets_base.h",
-    "geometry/insets_f.cc",
-    "geometry/insets_f.h",
-    "geometry/matrix3_f.cc",
-    "geometry/matrix3_f.h",
-    "geometry/point.cc",
-    "geometry/point.h",
-    "geometry/point3_f.cc",
-    "geometry/point3_f.h",
-    "geometry/point_base.h",
-    "geometry/point_conversions.cc",
-    "geometry/point_conversions.h",
-    "geometry/point_f.cc",
-    "geometry/point_f.h",
-    "geometry/quad_f.cc",
-    "geometry/quad_f.h",
-    "geometry/rect.cc",
-    "geometry/rect.h",
-    "geometry/rect_base.h",
-    "geometry/rect_base_impl.h",
-    "geometry/rect_conversions.cc",
-    "geometry/rect_conversions.h",
-    "geometry/rect_f.cc",
-    "geometry/rect_f.h",
-    "geometry/r_tree.cc",
-    "geometry/r_tree.h",
-    "geometry/safe_integer_conversions.h",
-    "geometry/size.cc",
-    "geometry/size.h",
-    "geometry/size_base.h",
-    "geometry/size_conversions.cc",
-    "geometry/size_conversions.h",
-    "geometry/size_f.cc",
-    "geometry/size_f.h",
-    "geometry/vector2d.cc",
-    "geometry/vector2d.h",
-    "geometry/vector2d_conversions.cc",
-    "geometry/vector2d_conversions.h",
-    "geometry/vector2d_f.cc",
-    "geometry/vector2d_f.h",
-    "geometry/vector3d_f.cc",
-    "geometry/vector3d_f.h",
-  ]
-  defines = [ "GFX_IMPLEMENTATION" ]
-  deps = [ "//base" ]
-}
+# Looking for gfx_geometry? It's //ui/gfx/geometry:geometry
 
 source_set("gfx_test_support") {
   sources = [
diff --git a/ui/gfx/geometry/BUILD.gn b/ui/gfx/geometry/BUILD.gn
index 9492ced..b7c877a 100644
--- a/ui/gfx/geometry/BUILD.gn
+++ b/ui/gfx/geometry/BUILD.gn
@@ -4,6 +4,7 @@
 
 component("geometry") {
   sources = [
+    "../gfx_export.h",
     "box_f.cc",
     "box_f.h",
     "cubic_bezier.h",
diff --git a/ui/gl/BUILD.gn b/ui/gl/BUILD.gn
index 70c5ad4..a0c58b1 100644
--- a/ui/gl/BUILD.gn
+++ b/ui/gl/BUILD.gn
@@ -113,7 +113,7 @@ component("gl") {
     ":generate_gl_bindings",
     "//base",
     "//base/third_party/dynamic_annotations",
-    "//gpu/command_buffer:gles2_utils",
+    "//gpu/command_buffer/common",
     "//skia",
     # TODO(GYP) hook up once this is converted.
     # Also uncomment forward statement below.