[Chromecast] Update GN files to support public Android Cast builds.

Now that the Clank GN build is stable, implement the GN targets needed
for a public ATV Cast build with GN.

BUG=516899
Bug:b/17615224

Review URL: https://codereview.chromium.org/1565923003

Cr-Commit-Position: refs/heads/master@{#372474}

12 files changed, 370 insertions, 95 deletions

diff --git a/chromecast/BUILD.gn b/chromecast/BUILD.gn
index 275480f..6c93d171 100644
--- a/chromecast/BUILD.gn
+++ b/chromecast/BUILD.gn
@@ -5,12 +5,17 @@
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
 import("//build/config/ui.gni")
+import("//build_overrides/v8.gni")
 import("//chromecast/build/tests/cast_test.gni")
 import("//chromecast/chromecast.gni")
 import("//media/media_options.gni")
 import("//tools/grit/repack.gni")
 import("//ui/ozone/ozone.gni")
 
+if (is_android) {
+  import("//build/config/android/rules.gni")
+}
+
 declare_args() {
   # TODO(slan): This most likely needs to be moved into a .gni file.
   use_chromecast_webui = true
@@ -31,8 +36,6 @@ cast_test_group("cast_tests") {
     "//chromecast/crypto:cast_crypto_unittests",
     "//content/test:content_unittests",
     "//crypto:crypto_unittests",
-    "//ipc:ipc_tests",
-    "//jingle:jingle_unittests",
     "//media:media_unittests",
     "//media/midi:midi_unittests",
     "//net:net_unittests",
@@ -42,7 +45,6 @@ cast_test_group("cast_tests") {
     "//sync:sync_unit_tests",
     "//third_party/cacheinvalidation:cacheinvalidation_unittests",
     "//ui/base:ui_base_unittests",
-    "//url:url_unittests",
   ]
 
   if (is_linux) {
@@ -108,6 +110,9 @@ cast_test_group("cast_tests") {
       "//chromecast/app:cast_shell_unittests",
       "//chromecast/browser:cast_shell_browser_test",
       "//chromecast/media:cast_media_unittests",
+      "//ipc:ipc_tests",
+      "//jingle:jingle_unittests",
+      "//url:url_unittests",
     ]
 
     # --enable-local-file-accesses => to load sample media files
@@ -282,3 +287,32 @@ action("chromecast_locales_pak") {
            rebase_path("$root_out_dir/chromecast_locales"),
          ] + locales
 }
+
+if (is_android) {
+  # GYP target: chromecast.gyp:cast_shell_icudata
+  android_assets("cast_shell_apk_assets") {
+    assert(v8_use_external_startup_data)
+
+    sources = [
+      "$root_out_dir/assets/cast_shell.pak",
+    ]
+
+    deps = [
+      ":cast_shell_pak",
+      "//third_party/icu:icu_assets",
+      "//v8:v8_external_startup_data_assets",
+    ]
+  }
+
+  # GYP target: chromecast.gyp:cast_shell_apk
+  android_apk("cast_shell_apk") {
+    apk_name = "CastShell"
+    android_manifest = "$root_gen_dir/cast_shell_manifest/AndroidManifest.xml"
+    android_manifest_dep = "//chromecast/browser/android:cast_shell_manifest"
+    deps = [
+      ":cast_shell_apk_assets",
+      "//chromecast/android:libcast_shell_android",
+      "//chromecast/browser/android:cast_shell_java",
+    ]
+  }
+}
diff --git a/chromecast/android/BUILD.gn b/chromecast/android/BUILD.gn
new file mode 100644
index 0000000..7c59b7d
--- /dev/null
+++ b/chromecast/android/BUILD.gn
@@ -0,0 +1,45 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//chromecast/chromecast.gni")
+
+# These targets shall only be referenced on Android builds.
+assert(is_android)
+
+# GYP target: chromecast.gyp:libcast_shell_android
+shared_library("libcast_shell_android") {
+  sources = [
+    "cast_jni_registrar.cc",
+    "cast_jni_registrar.h",
+    "cast_metrics_helper_android.cc",
+    "cast_metrics_helper_android.h",
+    "platform_jni_loader.h",
+
+    # TODO(slan): Move this into this folder.
+    "//chromecast/app/android/cast_jni_loader.cc",
+  ]
+
+  deps = [
+    "//base",
+    "//chromecast:cast_shell_common",
+    "//chromecast/app",
+    "//chromecast/app:cast_crash_client",
+    "//chromecast/base",
+    "//chromecast/base:cast_sys_info",
+    "//chromecast/base:jni_headers",
+    "//chromecast/base/metrics",
+    "//chromecast/browser",
+    "//chromecast/browser:jni_headers",
+    "//components/external_video_surface",
+    "//content/public/app:both",
+    "//content/public/browser",
+    "//skia",
+  ]
+
+  if (chromecast_branding != "public") {
+    deps += [ "//chromecast/internal:cast_shell_android_internal" ]
+  } else {
+    sources += [ "platform_jni_loader_stub.cc" ]
+  }
+}
diff --git a/chromecast/app/BUILD.gn b/chromecast/app/BUILD.gn
index 4388d89..4d5b8b3 100644
--- a/chromecast/app/BUILD.gn
+++ b/chromecast/app/BUILD.gn
@@ -30,6 +30,8 @@ source_set("cast_crash_client") {
   sources = [
     "android/cast_crash_reporter_client_android.cc",
     "android/cast_crash_reporter_client_android.h",
+    "android/crash_handler.cc",
+    "android/crash_handler.h",
     "linux/cast_crash_reporter_client.cc",
     "linux/cast_crash_reporter_client.h",
   ]
@@ -37,11 +39,20 @@ source_set("cast_crash_client") {
   deps = [
     "//base",
     "//chromecast/base",
+    "//chromecast/common",
     "//chromecast/crash",
     "//components/crash/content/app",
     "//components/crash/content/app:lib",
     "//content/public/common",
   ]
+
+  if (is_android) {
+    deps += [
+      "//breakpad:client",
+      "//chromecast/base:cast_version",
+      "//chromecast/browser:jni_headers",
+    ]
+  }
 }
 
 # TODO(kmackay) Consider renaming this.
@@ -62,6 +73,7 @@ test("cast_shell_unittests") {
   ]
 }
 
+# GYP target: chromecast.gyp:cast_shell_resources
 grit("resources") {
   source = "//chromecast/app/resources/shell_resources.grd"
 
diff --git a/chromecast/base/BUILD.gn b/chromecast/base/BUILD.gn
index 355c0da..2723b854 100644
--- a/chromecast/base/BUILD.gn
+++ b/chromecast/base/BUILD.gn
@@ -6,6 +6,10 @@ import("//chrome/version.gni")  # TODO layering violation!
 import("//chromecast/chromecast.gni")
 import("//testing/test.gni")
 
+if (is_android) {
+  import("//build/config/android/rules.gni")
+}
+
 # GYP target: chromecast.gyp:cast_base
 source_set("base") {
   sources = [
@@ -20,6 +24,8 @@ source_set("base") {
     "cast_paths.h",
     "cast_resource.cc",
     "cast_resource.h",
+    "chromecast_config_android.cc",
+    "chromecast_config_android.h",
     "chromecast_switches.cc",
     "chromecast_switches.h",
     "device_capabilities.h",
@@ -49,6 +55,10 @@ source_set("base") {
   deps = [
     "//base",
   ]
+
+  if (is_android) {
+    deps += [ ":jni_headers" ]
+  }
 }
 
 # GYP target: n/a
@@ -87,21 +97,26 @@ test("cast_base_unittests") {
 
 source_set("cast_sys_info") {
   sources = [
+    "cast_sys_info_android.cc",
+    "cast_sys_info_android.h",
     "cast_sys_info_dummy.cc",
     "cast_sys_info_dummy.h",
     "cast_sys_info_util.h",
   ]
 
-  if (chromecast_branding == "public" && !is_android) {
-    sources += [ "cast_sys_info_util_simple.cc" ]
-  }
-
-  # TODO(mbjorge): put cast_sys_info_android in here
-
   deps = [
     "//base",
     "//chromecast/public",
   ]
+
+  if (is_android) {
+    deps += [
+      ":cast_version",
+      "//chromecast/browser:jni_headers",
+    ]
+  } else if (chromecast_branding == "public") {
+    sources += [ "cast_sys_info_util_simple.cc" ]
+  }
 }
 
 process_version("cast_version") {
@@ -122,3 +137,31 @@ process_version("cast_version") {
     "CAST_PRODUCT_TYPE=0",
   ]
 }
+
+if (is_android) {
+  # GYP target: chromecast.gyp:jni_headers
+  generate_jni("jni_headers") {
+    sources = [
+      "java/src/org/chromium/chromecast/base/ChromecastConfigAndroid.java",
+      "java/src/org/chromium/chromecast/base/DumpstateWriter.java",
+      "java/src/org/chromium/chromecast/base/SystemTimeChangeNotifierAndroid.java",
+    ]
+
+    jni_package = "chromecast"
+  }
+
+  # GYP target: chromecast.gyp:cast_base_java
+  android_library("base_java") {
+    java_src_dir = "//chromecast/base/java/src"
+    java_files = [
+      "$java_src_dir/org/chromium/chromecast/base/CastSettingsManager.java",
+      "$java_src_dir/org/chromium/chromecast/base/ChromecastConfigAndroid.java",
+      "$java_src_dir/org/chromium/chromecast/base/DumpstateWriter.java",
+      "$java_src_dir/org/chromium/chromecast/base/SystemTimeChangeNotifierAndroid.java",
+    ]
+
+    deps = [
+      "//base:base_java",
+    ]
+  }
+}
diff --git a/chromecast/browser/BUILD.gn b/chromecast/browser/BUILD.gn
index c3524a7..afae1de 100644
--- a/chromecast/browser/BUILD.gn
+++ b/chromecast/browser/BUILD.gn
@@ -7,8 +7,16 @@ import("//media/media_options.gni")
 import("//testing/test.gni")
 import("//build/config/ui.gni")
 
+if (is_android) {
+  import("//build/config/android/rules.gni")
+}
+
 source_set("browser") {
   sources = [
+    "android/cast_window_android.cc",
+    "android/cast_window_android.h",
+    "android/cast_window_manager.cc",
+    "android/cast_window_manager.h",
     "cast_browser_context.cc",
     "cast_browser_context.h",
     "cast_browser_main_parts.cc",
@@ -61,18 +69,22 @@ source_set("browser") {
     ]
   }
 
+  public_deps = [
+    "//chromecast/browser/media",
+  ]
+
   deps = [
     "//base",
     "//base:i18n",
     "//base:prefs",
     "//cc",
+    "//chromecast/app:cast_crash_client",
     "//chromecast/app:chromecast_settings",
     "//chromecast/app:resources",
     "//chromecast/base",
     "//chromecast/base:cast_sys_info",
     "//chromecast/base:cast_version",
     "//chromecast/common",
-    "//chromecast/graphics",
     "//chromecast/media",
     "//chromecast/net",
     "//chromecast/service",
@@ -96,25 +108,27 @@ source_set("browser") {
     "//ipc",
     "//media",
     "//net",
-    "//ui/aura",
     "//ui/base",
     "//ui/compositor",
     "//ui/gl",
   ]
 
-  if (!is_android) {
+  if (is_linux) {
     sources += [
       "metrics/external_metrics.cc",
       "metrics/external_metrics.h",
     ]
 
-    public_deps = [
-      "//chromecast/browser/media",
-    ]
-
     deps += [
       "//build/linux:fontconfig",
+      "//chromecast/graphics",
       "//components/metrics:serialization",
+      "//ui/aura",
+    ]
+  } else if (is_android) {
+    deps += [
+      ":jni_headers",
+      "//components/external_video_surface",
     ]
   }
 
@@ -187,3 +201,17 @@ test("cast_shell_browser_test") {
     deps += [ "//chromecast/media/base:libcast_media_1.0_default_core" ]
   }
 }
+
+if (is_android) {
+  generate_jni("jni_headers") {
+    sources = [
+      "android/apk/src/org/chromium/chromecast/shell/CastCrashHandler.java",
+      "android/apk/src/org/chromium/chromecast/shell/CastMetricsHelper.java",
+      "android/apk/src/org/chromium/chromecast/shell/CastSysInfoAndroid.java",
+      "android/apk/src/org/chromium/chromecast/shell/CastWindowAndroid.java",
+      "android/apk/src/org/chromium/chromecast/shell/CastWindowManager.java",
+    ]
+
+    jni_package = "chromecast"
+  }
+}
diff --git a/chromecast/browser/android/BUILD.gn b/chromecast/browser/android/BUILD.gn
new file mode 100644
index 0000000..a739cea
--- /dev/null
+++ b/chromecast/browser/android/BUILD.gn
@@ -0,0 +1,54 @@
+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/rules.gni")
+
+assert(is_android)
+
+# GYP target: chromecast.gyp:cast_shell_manifest
+jinja_template("cast_shell_manifest") {
+  input = "apk/AndroidManifest.xml.jinja2"
+  output = "$root_gen_dir/cast_shell_manifest/AndroidManifest.xml"
+}
+
+# GYP target: n/a
+android_resources("cast_shell_android_resources") {
+  android_manifest = "$root_gen_dir/cast_shell_manifest/AndroidManifest.xml"
+  resource_dirs = [ "//chromecast/browser/android/apk/res" ]
+  deps = [
+    ":cast_shell_manifest",
+  ]
+}
+
+# GYP target: chromecast.gyp:cast_shell_java
+android_library("cast_shell_java") {
+  java_src_dir = "//chromecast/browser/android/apk/src"
+  java_files = [
+    "$java_src_dir/org/chromium/chromecast/shell/CastApplication.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastAudioManager.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastBrowserHelper.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastCrashHandler.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastCrashUploader.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastMetricsHelper.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastShellActivity.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastSwitches.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastSysInfoAndroid.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastWindowAndroid.java",
+    "$java_src_dir/org/chromium/chromecast/shell/CastWindowManager.java",
+  ]
+
+  deps = [
+    ":cast_shell_android_resources",
+    "//base:base_java",
+    "//chromecast/base:base_java",
+    "//components/external_video_surface:java",
+    "//content/public/android:content_java",
+    "//media/base/android:media_java",
+    "//net/android:net_java",
+
+    # TODO(slan): We may need to pass this in as a parameter.
+    "//third_party/android_tools:android_support_v13_java",
+    "//ui/android:ui_java",
+  ]
+}
diff --git a/chromecast/browser/media/BUILD.gn b/chromecast/browser/media/BUILD.gn
index a643e3a..5a177d5 100644
--- a/chromecast/browser/media/BUILD.gn
+++ b/chromecast/browser/media/BUILD.gn
@@ -10,10 +10,6 @@ source_set("media") {
     "cast_browser_cdm_factory.h",
     "cast_media_client_android.cc",
     "cast_media_client_android.h",
-    "cma_media_pipeline_client.cc",
-    "cma_media_pipeline_client.h",
-    "cma_message_filter_host.cc",
-    "cma_message_filter_host.h",
     "media_pipeline_host.cc",
     "media_pipeline_host.h",
   ]
@@ -30,4 +26,15 @@ source_set("media") {
     "//content/public/browser",
     "//media",
   ]
+
+  if (is_android) {
+    deps += [ "//components/cdm/browser" ]
+  } else {
+    sources += [
+      "cma_media_pipeline_client.cc",
+      "cma_media_pipeline_client.h",
+      "cma_message_filter_host.cc",
+      "cma_message_filter_host.h",
+    ]
+  }
 }
diff --git a/chromecast/chromecast.gyp b/chromecast/chromecast.gyp
index c94430a..38c4b85 100644
--- a/chromecast/chromecast.gyp
+++ b/chromecast/chromecast.gyp
@@ -180,10 +180,10 @@
         '../breakpad/src',
       ],
       'sources' : [
-        'app/android/crash_handler.cc',
-        'app/android/crash_handler.h',
         'app/android/cast_crash_reporter_client_android.cc',
         'app/android/cast_crash_reporter_client_android.h',
+        'app/android/crash_handler.cc',
+        'app/android/crash_handler.h',
         'app/linux/cast_crash_reporter_client.cc',
         'app/linux/cast_crash_reporter_client.h',
       ],
@@ -230,6 +230,7 @@
         }],
       ],
     },
+    # GN target: //chromecast/app:resources
     {
       'target_name': 'cast_shell_resources',
       'type': 'none',
@@ -248,6 +249,7 @@
       ],
       'includes': [ '../build/grit_target.gypi' ],
     },
+    # GN target: //chromecast:cast_shell_pak
     {
       'target_name': 'cast_shell_pak',
       'type': 'none',
@@ -311,6 +313,7 @@
     },  # end of target 'cast_shell_pak'
     # This target contains all content-embedder implementation that is
     # non-platform-specific.
+    # GN target: This target is dissolved into many targets on GN.
     {
       'target_name': 'cast_shell_common',
       'type': '<(component)',
@@ -463,6 +466,7 @@
         }],
       ],
     },
+    # GN target: //chromecast/base:cast_sys_info
     {
       'target_name': 'cast_sys_info',
       'type': '<(component)',
@@ -491,6 +495,7 @@
         }],
       ],
     },  # end of target 'cast_sys_info'
+    # GN target: //chromecast/base:cast_version_header
     {
       'target_name': 'cast_version_header',
       'type': 'none',
diff --git a/chromecast/common/media/BUILD.gn b/chromecast/common/media/BUILD.gn
index a2052cd..c92ba86 100644
--- a/chromecast/common/media/BUILD.gn
+++ b/chromecast/common/media/BUILD.gn
@@ -2,29 +2,60 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+# CMA is not used on Android; exclude CMA-specific targets.
+enable_cma = !is_android
+
+# GYP target: chromecast.gyp:cast_shell_media
 source_set("media") {
   sources = [
-    "cast_message_generator.cc",
-    "cast_message_generator.h",
-    "cast_messages.h",
-    "cma_ipc_common.h",
-    "cma_message_generator.cc",
-    "cma_message_generator.h",
-    "cma_messages.h",
-    "cma_param_traits.cc",
-    "cma_param_traits.h",
-    "cma_param_traits_macros.h",
     "shared_memory_chunk.cc",
     "shared_memory_chunk.h",
   ]
 
+  public_deps = [
+    ":cast_messages",
+  ]
+  if (enable_cma) {
+    public_deps += [ ":cma_messages" ]
+  }
+
   deps = [
     "//base",
-    "//chromecast/media",
-    "//content/public/common",
+    "//chromecast/media/cma/ipc",
+  ]
+}
+
+# GYP target: chromecast.gyp:cast_shell_common
+source_set("cast_messages") {
+  sources = [
+    "cast_message_generator.cc",
+    "cast_message_generator.h",
+    "cast_messages.h",
+  ]
+  deps = [
     "//ipc",
-    "//media",
-    "//media:shared_memory_support",
-    "//ui/gfx/ipc",
   ]
 }
+
+if (enable_cma) {
+  # GYP target: chromecast.gyp:cast_shell_media
+  source_set("cma_messages") {
+    sources = [
+      "cma_ipc_common.h",
+      "cma_message_generator.cc",
+      "cma_message_generator.h",
+      "cma_messages.h",
+      "cma_param_traits.cc",
+      "cma_param_traits.h",
+      "cma_param_traits_macros.h",
+    ]
+
+    deps = [
+      "//chromecast/media/cma/pipeline",
+      "//content/public/common",
+      "//media",
+      "//media:shared_memory_support",
+      "//ui/gfx/ipc",
+    ]
+  }
+}
diff --git a/chromecast/graphics/BUILD.gn b/chromecast/graphics/BUILD.gn
index 66b4d64..1d42322 100644
--- a/chromecast/graphics/BUILD.gn
+++ b/chromecast/graphics/BUILD.gn
@@ -3,18 +3,21 @@
 # found in the LICENSE file.
 
 import("//chromecast/chromecast.gni")
+import("//build/config/ui.gni")
 
-source_set("graphics") {
-  sources = [
-    "cast_screen.cc",
-    "cast_screen.h",
-  ]
+if (use_aura) {
+  source_set("graphics") {
+    sources = [
+      "cast_screen.cc",
+      "cast_screen.h",
+    ]
 
-  deps = [
-    "//ui/aura",
-    "//ui/gfx",
-    "//ui/gfx/geometry",
-  ]
+    deps = [
+      "//ui/aura",
+      "//ui/gfx",
+      "//ui/gfx/geometry",
+    ]
+  }
 }
 
 shared_library("libcast_graphics_1.0") {
diff --git a/chromecast/renderer/BUILD.gn b/chromecast/renderer/BUILD.gn
index ae6dfa3..92cf3ef 100644
--- a/chromecast/renderer/BUILD.gn
+++ b/chromecast/renderer/BUILD.gn
@@ -16,16 +16,14 @@ source_set("renderer") {
     "key_systems_cast.h",
   ]
 
+  public_deps = [
+    "//chromecast/renderer/media",
+  ]
+
   if (chromecast_branding == "public") {
     sources += [ "cast_content_renderer_client_simple.cc" ]
   }
 
-  if (!is_android) {
-    public_deps = [
-      "//chromecast/renderer/media",
-    ]
-  }
-
   if (use_playready) {
     configs += [ "//chromecast:playready_config" ]
   }
diff --git a/chromecast/renderer/media/BUILD.gn b/chromecast/renderer/media/BUILD.gn
index 0e127f3..cc521b7 100644
--- a/chromecast/renderer/media/BUILD.gn
+++ b/chromecast/renderer/media/BUILD.gn
@@ -4,60 +4,75 @@
 
 import("//testing/test.gni")
 
+# All Chromecast platforms except Android should support the CMA pipeline by
+# default for media playback.
+enable_cma = !is_android
+
 source_set("media") {
   sources = [
-    "audio_pipeline_proxy.cc",
-    "audio_pipeline_proxy.h",
     "capabilities_message_filter.cc",
     "capabilities_message_filter.h",
-    "chromecast_media_renderer_factory.cc",
-    "chromecast_media_renderer_factory.h",
-    "cma_message_filter_proxy.cc",
-    "cma_message_filter_proxy.h",
-    "cma_renderer.cc",
-    "cma_renderer.h",
-    "demuxer_stream_adapter.cc",
-    "demuxer_stream_adapter.h",
-    "hole_frame_factory.cc",
-    "hole_frame_factory.h",
-    "media_channel_proxy.cc",
-    "media_channel_proxy.h",
-    "media_pipeline_proxy.cc",
-    "media_pipeline_proxy.h",
-    "video_pipeline_proxy.cc",
-    "video_pipeline_proxy.h",
   ]
 
   deps = [
     "//base",
     "//chromecast/common/media",
-    "//chromecast/media",
-    "//content/public/renderer",
-    "//gpu/command_buffer/client:gles2_interface",
-    "//gpu/command_buffer/common",
+    "//chromecast/media/base",
     "//ipc",
-    "//media",
-    "//ui/gfx/geometry",
   ]
+
+  if (enable_cma) {
+    sources += [
+      "audio_pipeline_proxy.cc",
+      "audio_pipeline_proxy.h",
+      "chromecast_media_renderer_factory.cc",
+      "chromecast_media_renderer_factory.h",
+      "cma_message_filter_proxy.cc",
+      "cma_message_filter_proxy.h",
+      "cma_renderer.cc",
+      "cma_renderer.h",
+      "demuxer_stream_adapter.cc",
+      "demuxer_stream_adapter.h",
+      "hole_frame_factory.cc",
+      "hole_frame_factory.h",
+      "media_channel_proxy.cc",
+      "media_channel_proxy.h",
+      "media_pipeline_proxy.cc",
+      "media_pipeline_proxy.h",
+      "video_pipeline_proxy.cc",
+      "video_pipeline_proxy.h",
+    ]
+
+    deps += [
+      "//chromecast/media",
+      "//content/public/renderer",
+      "//gpu/command_buffer/client:gles2_interface",
+      "//gpu/command_buffer/common",
+      "//media",
+      "//ui/gfx/geometry",
+    ]
+  }
 }
 
-# GYP target: chromecast_tests.gypi:cast_renderer_media_unittests
-test("cast_renderer_media_unittests") {
-  sources = [
-    "demuxer_stream_adapter_unittest.cc",
-    "demuxer_stream_for_test.cc",
-    "demuxer_stream_for_test.h",
-    "multi_demuxer_stream_adapter_unittest.cc",
-  ]
+if (enable_cma) {
+  # GYP target: chromecast_tests.gypi:cast_renderer_media_unittests
+  test("cast_renderer_media_unittests") {
+    sources = [
+      "demuxer_stream_adapter_unittest.cc",
+      "demuxer_stream_for_test.cc",
+      "demuxer_stream_for_test.h",
+      "multi_demuxer_stream_adapter_unittest.cc",
+    ]
 
-  deps = [
-    ":media",
-    "//base",
-    "//base/test:run_all_unittests",
-    "//base/test:test_support",
-    "//chromecast/media/cma/base",
-    "//chromecast/public/media",
-    "//media",
-    "//testing/gtest:gtest",
-  ]
+    deps = [
+      ":media",
+      "//base",
+      "//base/test:run_all_unittests",
+      "//base/test:test_support",
+      "//chromecast/media/cma/base",
+      "//chromecast/public/media",
+      "//media",
+      "//testing/gtest:gtest",
+    ]
+  }
 }