Adding reduced version of sdk at 1387 to chrome tree.

BUG=None
TEST=None
R=noelallen@google.com

TBR

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@110822 0039d316-1c4b-4281-b951-d872f2087c98

1 files changed, 51 insertions, 0 deletions

diff --git a/native_client_sdk/src/examples/load_progress/build.scons b/native_client_sdk/src/examples/load_progress/build.scons
new file mode 100644
index 0000000..1c8a6a6
--- /dev/null
+++ b/native_client_sdk/src/examples/load_progress/build.scons
@@ -0,0 +1,51 @@
+#! -*- python -*-
+#
+# Copyright (c) 2011 The Native Client Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import make_nacl_env
+import os
+
+nacl_env = make_nacl_env.NaClEnvironment(
+    use_c_plus_plus_libs=True, nacl_platform=os.getenv('NACL_TARGET_PLATFORM'),
+    install_subdir='load_progress', lib_prefix='..')
+nacl_env.Append(
+    # Add a CPPPATH that enables the full-path #include directives, such as
+    # #include "examples/sine_synth/sine_synth.h"
+    CPPPATH=[os.path.dirname(os.path.dirname(os.getcwd()))],
+    # Strict ANSI compliance.
+    CCFLAGS=['-pedantic', '-Werror'],
+   )
+
+sources = ['load_progress.cc']
+
+opt_nexes, dbg_nexes = nacl_env.AllNaClModules(sources, 'load_progress')
+
+# This target is used by the SDK build system to provide a prebuilt version
+# of the example in the SDK installer.
+nacl_env.InstallPrebuilt('load_progress')
+
+common_files = [
+    'check_browser.js',
+    ]
+common_files = [
+    os.path.join(os.path.dirname(os.getcwd()), 'common', common_file)
+    for common_file in common_files]
+
+app_files = [
+    'load_progress.html',
+    'load_progress.nmf',
+    ]
+
+# Split the install of the .nexes from the other app sources so that the strip
+# action is applied to the .nexes only.
+install_nexes = nacl_env.NaClStrippedInstall(dir=nacl_env['NACL_INSTALL_ROOT'],
+                                             source=opt_nexes)
+install_app = nacl_env.Install(dir=nacl_env['NACL_INSTALL_ROOT'],
+                               source=app_files)
+common_dir = os.path.join(os.path.dirname(nacl_env['NACL_INSTALL_ROOT']),
+                          'common')
+install_common = nacl_env.Install(dir=common_dir, source=common_files)
+nacl_env.Alias('install',
+               source=[install_app, install_common, install_nexes])