Add metro driver and delegate_execute to GN build.

This also makes //win8/* pass "gn check".

BUG=512864,512869

Review URL: https://codereview.chromium.org/1464263003

Cr-Commit-Position: refs/heads/master@{#361211}

8 files changed, 271 insertions, 21 deletions

diff --git a/win8/BUILD.gn b/win8/BUILD.gn
index 1d4343d..fb43d2d 100644
--- a/win8/BUILD.gn
+++ b/win8/BUILD.gn
@@ -10,29 +10,24 @@ source_set("metro_viewer_constants") {
 }
 
 component("metro_viewer") {
-  deps = [
-    ":metro_viewer_constants",
-    "//base",
-    "//ipc",
-    "//ui/aura",
-    "//ui/metro_viewer",
-  ]
   sources = [
     "viewer/metro_viewer_process_host.cc",
     "viewer/metro_viewer_process_host.h",
   ]
+
   defines = [ "METRO_VIEWER_IMPLEMENTATION" ]
-}
 
-source_set("test_support_win8") {
   deps = [
-    ":test_registrar_constants",
+    ":metro_viewer_constants",
     "//base",
+    "//ipc",
+    "//ui/aura",
+    "//ui/gfx",
+    "//ui/metro_viewer",
   ]
+}
 
-  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
-  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
-
+source_set("test_support_win8") {
   sources = [
     "test/open_with_dialog_async.cc",
     "test/open_with_dialog_async.h",
@@ -41,6 +36,14 @@ source_set("test_support_win8") {
     "test/ui_automation_client.cc",
     "test/ui_automation_client.h",
   ]
+
+  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+  deps = [
+    ":test_registrar_constants",
+    "//base",
+  ]
 }
 
 source_set("test_registrar_constants") {
@@ -51,6 +54,16 @@ source_set("test_registrar_constants") {
 }
 
 executable("test_registrar") {
+  sources = [
+    "test/test_registrar.cc",
+    "test/test_registrar.rc",
+    "test/test_registrar.rgs",
+    "test/test_registrar_resource.h",
+  ]
+
+  configs -= [ "//build/config/win:console" ]
+  configs += [ "//build/config/win:windowed" ]
+
   deps = [
     ":test_registrar_constants",
     "//base",
@@ -61,11 +74,4 @@ executable("test_registrar") {
     # process.
     "//chrome",
   ]
-  sources = [
-    "test/test_registrar.cc",
-    "test/test_registrar.rc",
-    "test/test_registrar.rgs",
-    "test/test_registrar_resource.h",
-  ]
-  configs += [ "//build/config/win:windowed" ]
 }
diff --git a/win8/delegate_execute/BUILD.gn b/win8/delegate_execute/BUILD.gn
new file mode 100644
index 0000000..87cc1b1
--- /dev/null
+++ b/win8/delegate_execute/BUILD.gn
@@ -0,0 +1,79 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/chrome_build.gni")
+import("//build/config/ui.gni")
+import("//chrome/version.gni")
+import("//testing/test.gni")
+
+executable("delegate_execute") {
+  sources = [
+    "delegate_execute.cc",
+    "delegate_execute.rc",
+  ]
+
+  configs -= [ "//build/config/win:console" ]
+  configs += [ "//build/config/win:windowed" ]
+
+  deps = [
+    ":lib",
+    ":version_resources",
+  ]
+}
+
+source_set("lib") {
+  visibility = [ ":*" ]
+  sources = [
+    "chrome_util.cc",
+    "chrome_util.h",
+    "command_execute_impl.cc",
+    "command_execute_impl.h",
+    "command_execute_impl.rgs",
+    "crash_server_init.cc",
+    "crash_server_init.h",
+    "delegate_execute_operation.cc",
+    "delegate_execute_operation.h",
+    "delegate_execute_util.cc",
+    "delegate_execute_util.h",
+    "resource.h",
+  ]
+
+  public_deps = [
+    "//base",
+    "//breakpad:breakpad_handler",
+    "//chrome/common:constants",
+    "//chrome/installer/util",
+    "//ui/base",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+  ]
+
+  if (use_aura) {
+    public_deps += [ "//win8:metro_viewer_constants" ]
+  }
+
+  if (is_chrome_branded) {
+    public_deps += [ "//google_update" ]
+  }
+}
+
+process_version("version_resources") {
+  visibility = [ ":*" ]
+  sources = [
+    "delegate_execute_exe.ver",
+  ]
+  output = "$target_gen_dir/delegate_execute_exe.rc"
+  template_file = chrome_version_rc_template
+}
+
+test("delegate_execute_unittests") {
+  sources = [
+    "delegate_execute_util_unittest.cc",
+  ]
+  deps = [
+    ":lib",
+    "//base/test:run_all_unittests",
+    "//testing/gtest",
+  ]
+}
diff --git a/win8/delegate_execute/chrome_util.cc b/win8/delegate_execute/chrome_util.cc
index 858a2ca..247bb58 100644
--- a/win8/delegate_execute/chrome_util.cc
+++ b/win8/delegate_execute/chrome_util.cc
@@ -29,7 +29,7 @@
 #include "chrome/installer/util/util_constants.h"
 
 #if defined(GOOGLE_CHROME_BUILD)
-#include "google_update/google_update_idl.h"
+#include "google_update/google_update_idl.h"  // nogncheck
 #endif
 
 namespace {
diff --git a/win8/delegate_execute/delegate_execute.gyp b/win8/delegate_execute/delegate_execute.gyp
index 7247e08..8869fa4 100644
--- a/win8/delegate_execute/delegate_execute.gyp
+++ b/win8/delegate_execute/delegate_execute.gyp
@@ -11,6 +11,7 @@
   ],
   'targets': [
     {
+      # GN version: //win8/delegate_execute:version_resources
       'target_name': 'delegate_execute_version_resources',
       'type': 'none',
       'conditions': [
@@ -36,6 +37,7 @@
       ],
     },
     {
+      # GN version: //win8/delegate_execute
       'target_name': 'delegate_execute',
       'type': 'executable',
       'dependencies': [
@@ -85,6 +87,7 @@
       ],
     },
     {
+      # GN version: //win8/delegate_execute:delegate_execute_unittests
       'target_name': 'delegate_execute_unittests',
       'type': 'executable',
       'dependencies': [
diff --git a/win8/metro_driver/BUILD.gn b/win8/metro_driver/BUILD.gn
new file mode 100644
index 0000000..519259e
--- /dev/null
+++ b/win8/metro_driver/BUILD.gn
@@ -0,0 +1,128 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+import("//chrome/version.gni")
+import("//testing/test.gni")
+
+shared_library("metro_driver") {
+  sources = [
+    "display_properties.cc",
+    "display_properties.h",
+    "metro_driver.cc",
+    "metro_driver.h",
+    "metro_driver_win7.cc",
+    "stdafx.h",
+    "winrt_utils.cc",
+    "winrt_utils.h",
+  ]
+
+  deps = [
+    ":copy_resources",
+    ":version_resources",
+    "//base",
+    "//chrome/common:constants",
+    "//chrome/installer/util",
+    "//crypto",
+    "//ipc",
+    "//sandbox",
+    "//ui/events",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+    "//ui/metro_viewer",
+    "//url",
+  ]
+
+  if (use_aura) {
+    sources += [
+      "chrome_app_view_ash.cc",
+      "chrome_app_view_ash.h",
+      "direct3d_helper.cc",
+      "direct3d_helper.h",
+      "file_picker_ash.cc",
+      "file_picker_ash.h",
+    ]
+
+    deps += [
+      "//ui/events:gesture_detection",
+      "//win8:metro_viewer_constants",
+      "//win8/metro_driver/ime",
+    ]
+  } else {
+    sources = [
+      "chrome_app_view.cc",
+      "chrome_app_view.h",
+      "chrome_url_launch_handler.cc",
+      "chrome_url_launch_handler.h",
+      "devices_handler.cc",
+      "devices_handler.h",
+      "file_picker.cc",
+      "file_picker.h",
+      "metro_dialog_box.cc",
+      "metro_dialog_box.h",
+      "print_document_source.cc",
+      "print_document_source.h",
+      "print_handler.cc",
+      "print_handler.h",
+      "secondary_tile.cc",
+      "secondary_tile.h",
+      "settings_handler.cc",
+      "settings_handler.h",
+      "toast_notification_handler.cc",
+      "toast_notification_handler.h",
+    ]
+  }
+
+  libs = [
+    "D2D1.lib",
+    "D3D11.lib",
+    "runtimeobject.lib",
+  ]
+
+  ldflags = [
+    "/DELAYLOAD:API-MS-WIN-CORE-WINRT-ERROR-L1-1-0.DLL",
+    "/DELAYLOAD:API-MS-WIN-CORE-WINRT-L1-1-0.DLL",
+    "/DELAYLOAD:API-MS-WIN-CORE-WINRT-STRING-L1-1-0.DLL",
+  ]
+}
+
+process_version("version_resources") {
+  visibility = [ ":*" ]
+  sources = [
+    "metro_driver_dll.ver",
+  ]
+  output = "$target_gen_dir/metro_driver_dll_version.rc"
+  template_file = chrome_version_rc_template
+}
+
+copy("copy_resources") {
+  visibility = [ ":*" ]
+
+  sources = [
+    "resources/Logo.png",
+    "resources/SecondaryTile.png",
+    "resources/SmallLogo.png",
+    "resources/chrome.VisualElementsManifest.xml",
+  ]
+
+  outputs = [
+    "$root_out_dir/{{source_file_part}}",
+  ]
+}
+
+test("metro_driver_unittests") {
+  sources = [
+    "run_all_unittests.cc",
+    "winrt_utils.cc",
+    "winrt_utils.h",
+    "winrt_utils_unittest.cc",
+  ]
+
+  deps = [
+    ":metro_driver",
+    "//base",
+    "//chrome/installer/util",
+    "//testing/gtest",
+  ]
+}
diff --git a/win8/metro_driver/ime/BUILD.gn b/win8/metro_driver/ime/BUILD.gn
new file mode 100644
index 0000000..63ebd99
--- /dev/null
+++ b/win8/metro_driver/ime/BUILD.gn
@@ -0,0 +1,29 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("ime") {
+  visibility = [ "//win8/metro_driver/*" ]
+  sources = [
+    "ime_popup_monitor.cc",
+    "ime_popup_monitor.h",
+    "ime_popup_observer.h",
+    "input_scope.cc",
+    "input_scope.h",
+    "input_source.cc",
+    "input_source.h",
+    "input_source_observer.h",
+    "text_service.cc",
+    "text_service.h",
+    "text_service_delegate.h",
+    "text_store.cc",
+    "text_store.h",
+    "text_store_delegate.h",
+  ]
+
+  deps = [
+    "//base",
+    "//ui/base",
+    "//ui/metro_viewer",
+  ]
+}
diff --git a/win8/metro_driver/ime/ime.gypi b/win8/metro_driver/ime/ime.gypi
index ba9db46..f5d489c 100644
--- a/win8/metro_driver/ime/ime.gypi
+++ b/win8/metro_driver/ime/ime.gypi
@@ -3,6 +3,7 @@
 # found in the LICENSE file.
 
 {
+  # GN version: //win8/metro_driver/ime
   'sources': [
     'ime_popup_monitor.cc',
     'ime_popup_monitor.h',
diff --git a/win8/metro_driver/metro_driver.gyp b/win8/metro_driver/metro_driver.gyp
index c58ae33..caa5ab5 100644
--- a/win8/metro_driver/metro_driver.gyp
+++ b/win8/metro_driver/metro_driver.gyp
@@ -29,6 +29,7 @@
       },
       'targets': [
         {
+          # GN version: //win8/metro_driver:version_resources
           'target_name': 'metro_driver_version_resources',
           'type': 'none',
           'variables': {
@@ -44,6 +45,7 @@
           ],
         },
         {
+          # GN version: //win8/metro_driver
           'target_name': 'metro_driver',
           'type': 'shared_library',
           'dependencies': [
@@ -114,6 +116,7 @@
           ],
           'copies': [
             {
+              # GN version: //win8/metro_viewer:copy_resources
               'destination': '<(PRODUCT_DIR)',
               'files': [
                 'resources/Logo.png',
@@ -125,6 +128,7 @@
           ],
         },
         {
+          # GN version: //win8/metro_driver:metro_driver_unittests
           'target_name': 'metro_driver_unittests',
           'type': 'executable',
           'dependencies': [