1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
|
// Copyright (c) 2011 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#include <string>
#include "base/mac/cocoa_protocols.h"
#include "base/memory/scoped_nsobject.h"
#include "base/memory/singleton.h"
#include "base/sys_string_conversions.h"
#include "base/values.h"
#include "chrome/browser/extensions/extension_function.h"
#include "chrome/browser/extensions/extension_tts_api_constants.h"
#include "chrome/browser/extensions/extension_tts_api_controller.h"
#include "chrome/browser/extensions/extension_tts_api_platform.h"
#import <Cocoa/Cocoa.h>
class ExtensionTtsPlatformImplMac;
@interface ChromeTtsDelegate : NSObject <NSSpeechSynthesizerDelegate> {
@private
ExtensionTtsPlatformImplMac* ttsImplMac_; // weak.
}
- (id)initWithPlatformImplMac:(ExtensionTtsPlatformImplMac*)ttsImplMac;
@end
class ExtensionTtsPlatformImplMac : public ExtensionTtsPlatformImpl {
public:
virtual bool PlatformImplAvailable() {
return true;
}
virtual bool Speak(
int utterance_id,
const std::string& utterance,
const std::string& lang,
const UtteranceContinuousParameters& params);
virtual bool StopSpeaking();
virtual bool IsSpeaking();
virtual bool SendsEvent(TtsEventType event_type);
// Called by ChromeTtsDelegate when we get a callback from the
// native speech engine.
void OnSpeechEvent(NSSpeechSynthesizer* sender,
TtsEventType event_type,
int char_index,
const std::string& error_message);
// Get the single instance of this class.
static ExtensionTtsPlatformImplMac* GetInstance();
private:
ExtensionTtsPlatformImplMac();
virtual ~ExtensionTtsPlatformImplMac();
scoped_nsobject<NSSpeechSynthesizer> speech_synthesizer_;
scoped_nsobject<ChromeTtsDelegate> delegate_;
int utterance_id_;
std::string utterance_;
bool sent_start_event_;
friend struct DefaultSingletonTraits<ExtensionTtsPlatformImplMac>;
DISALLOW_COPY_AND_ASSIGN(ExtensionTtsPlatformImplMac);
};
// static
ExtensionTtsPlatformImpl* ExtensionTtsPlatformImpl::GetInstance() {
return ExtensionTtsPlatformImplMac::GetInstance();
}
bool ExtensionTtsPlatformImplMac::Speak(
int utterance_id,
const std::string& utterance,
const std::string& lang,
const UtteranceContinuousParameters& params) {
// Deliberately construct a new speech synthesizer every time Speak is
// called, otherwise there's no way to know whether calls to the delegate
// apply to the current utterance or a previous utterance. In
// experimentation, the overhead of constructing and destructing a
// NSSpeechSynthesizer is minimal.
speech_synthesizer_.reset([[NSSpeechSynthesizer alloc] init]);
[speech_synthesizer_ setDelegate:delegate_];
utterance_id_ = utterance_id;
sent_start_event_ = false;
// TODO: convert SSML to SAPI xml. http://crbug.com/88072
utterance_ = utterance;
// TODO: support languages other than the default: crbug.com/88059
if (params.rate >= 0.0) {
// The TTS api defines rate via words per minute. Let 200 be the default.
[speech_synthesizer_
setObject:[NSNumber numberWithInt:params.rate * 200]
forProperty:NSSpeechRateProperty error:nil];
}
if (params.pitch >= 0.0) {
// The TTS api allows an approximate range of 30 to 65 for speech pitch.
[speech_synthesizer_
setObject: [NSNumber numberWithInt:(params.pitch * 17 + 30)]
forProperty:NSSpeechPitchBaseProperty error:nil];
}
if (params.volume >= 0.0) {
[speech_synthesizer_
setObject: [NSNumber numberWithFloat:params.volume]
forProperty:NSSpeechVolumeProperty error:nil];
}
return [speech_synthesizer_ startSpeakingString:
[NSString stringWithUTF8String: utterance.c_str()]];
}
bool ExtensionTtsPlatformImplMac::StopSpeaking() {
if (speech_synthesizer_.get()) {
[speech_synthesizer_ stopSpeaking];
speech_synthesizer_.reset(nil);
}
return true;
}
bool ExtensionTtsPlatformImplMac::IsSpeaking() {
// Note: this is OK even if speech_synthesizer_ is nil, it will return false.
return [speech_synthesizer_ isSpeaking];
}
bool ExtensionTtsPlatformImplMac::SendsEvent(TtsEventType event_type) {
return (event_type == TTS_EVENT_START ||
event_type == TTS_EVENT_END ||
event_type == TTS_EVENT_WORD ||
event_type == TTS_EVENT_ERROR);
}
void ExtensionTtsPlatformImplMac::OnSpeechEvent(
NSSpeechSynthesizer* sender,
TtsEventType event_type,
int char_index,
const std::string& error_message) {
// Don't send events from an utterance that's already completed.
// This depends on the fact that we construct a new NSSpeechSynthesizer
// each time we call Speak.
if (sender != speech_synthesizer_.get())
return;
if (event_type == TTS_EVENT_END)
char_index = utterance_.size();
ExtensionTtsController* controller = ExtensionTtsController::GetInstance();
if (event_type == TTS_EVENT_WORD && !sent_start_event_) {
controller->OnTtsEvent(
utterance_id_, TTS_EVENT_START, 0, "");
sent_start_event_ = true;
}
controller->OnTtsEvent(
utterance_id_, event_type, char_index, error_message);
}
ExtensionTtsPlatformImplMac::ExtensionTtsPlatformImplMac() {
utterance_id_ = -1;
sent_start_event_ = true;
delegate_.reset([[ChromeTtsDelegate alloc] initWithPlatformImplMac:this]);
}
ExtensionTtsPlatformImplMac::~ExtensionTtsPlatformImplMac() {
}
// static
ExtensionTtsPlatformImplMac* ExtensionTtsPlatformImplMac::GetInstance() {
return Singleton<ExtensionTtsPlatformImplMac>::get();
}
@implementation ChromeTtsDelegate
- (id)initWithPlatformImplMac:(ExtensionTtsPlatformImplMac*)ttsImplMac {
if ((self = [super init])) {
ttsImplMac_ = ttsImplMac;
}
return self;
}
- (void)speechSynthesizer:(NSSpeechSynthesizer*)sender
didFinishSpeaking:(BOOL)finished_speaking {
ttsImplMac_->OnSpeechEvent(sender, TTS_EVENT_END, 0, "");
}
- (void)speechSynthesizer:(NSSpeechSynthesizer*)sender
willSpeakWord:(NSRange)character_range
ofString:(NSString*)string {
ttsImplMac_->OnSpeechEvent(sender, TTS_EVENT_WORD,
character_range.location, "");
}
- (void)speechSynthesizer:(NSSpeechSynthesizer*)sender
didEncounterErrorAtIndex:(NSUInteger)character_index
ofString:(NSString*)string
message:(NSString*)message {
std::string message_utf8 = base::SysNSStringToUTF8(message);
ttsImplMac_->OnSpeechEvent(sender, TTS_EVENT_ERROR, character_index,
message_utf8);
}
@end
|
