chrome/browser/ui/cocoa/extensions/extension_install_dialog_controller.mm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

// Copyright (c) 2012 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.

#import "chrome/browser/ui/cocoa/extensions/extension_install_dialog_controller.h"

#include "chrome/browser/ui/browser.h"
#include "chrome/browser/ui/browser_finder.h"
#import "chrome/browser/ui/cocoa/constrained_window/constrained_window_controller.h"
#import "chrome/browser/ui/cocoa/extensions/extension_install_view_controller.h"
#include "chrome/browser/ui/tab_contents/tab_contents.h"
#include "chrome/browser/ui/tabs/tab_strip_model.h"

namespace {

void ShowExtensionInstallDialogImpl(
    gfx::NativeWindow parent,
    content::PageNavigator* navigator,
    ExtensionInstallPrompt::Delegate* delegate,
    const ExtensionInstallPrompt::Prompt& prompt) {
  // TODO(sail) Update ShowExtensionInstallDialogImpl to take a web contents.
  Browser* browser = browser::FindBrowserWithWindow(parent);
  if (!browser)
    return;
  TabContents* tab = browser->tab_strip_model()->GetActiveTabContents();
  if (!tab)
    return;

  // This object will delete itself when the dialog closes.
  new ExtensionInstallDialogController(tab->web_contents(),
                                       navigator,
                                       delegate,
                                       prompt);
}

}  // namespace

ExtensionInstallDialogController::ExtensionInstallDialogController(
    content::WebContents* webContents,
    content::PageNavigator* navigator,
    ExtensionInstallPrompt::Delegate* delegate,
    const ExtensionInstallPrompt::Prompt& prompt) : delegate_(delegate) {
  view_controller_.reset([[ExtensionInstallViewController alloc]
      initWithNavigator:navigator
               delegate:this
                 prompt:prompt]);
  window_controller_.reset([[ConstrainedWindowController alloc]
      initWithParentWebContents:webContents
                   embeddedView:[view_controller_ view]]);
}

ExtensionInstallDialogController::~ExtensionInstallDialogController() {
}

void ExtensionInstallDialogController::InstallUIProceed() {
  delegate_->InstallUIProceed();
  [window_controller_ close];
  delete this;
}

void ExtensionInstallDialogController::InstallUIAbort(bool user_initiated) {
  delegate_->InstallUIAbort(user_initiated);
  [window_controller_ close];
  delete this;
}

// static
ExtensionInstallPrompt::ShowDialogCallback
ExtensionInstallPrompt::GetDefaultShowDialogCallback() {
  return base::Bind(&ShowExtensionInstallDialogImpl);
}