blob: 0f889d161f8df5eeab8f23e934fd3953c99468c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
|
// Copyright 2014 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#include "components/handoff/handoff_manager.h"
#include "base/logging.h"
#include "base/mac/scoped_nsobject.h"
#include "net/base/mac/url_conversions.h"
#if defined(OS_IOS)
#include "base/ios/ios_util.h"
#endif
#if defined(OS_MACOSX) && !defined(OS_IOS)
#include "base/mac/mac_util.h"
#include "base/mac/sdk_forward_declarations.h"
#endif
@interface HandoffManager ()
// The active user activity.
@property(nonatomic, retain) NSUserActivity* userActivity;
// Whether the URL of the current tab should be exposed for Handoff.
- (BOOL)shouldUseActiveURL;
// Updates the active NSUserActivity.
- (void)updateUserActivity;
@end
@implementation HandoffManager
@synthesize userActivity = _userActivity;
- (instancetype)init {
self = [super init];
if (self) {
_propertyReleaser_HandoffManager.Init(self, [HandoffManager class]);
#if defined(OS_MACOSX) && !defined(OS_IOS)
_origin = handoff::ORIGIN_MAC;
#elif defined(OS_IOS)
_origin = handoff::ORIGIN_IOS;
#else
NOTREACHED();
#endif
}
return self;
}
- (void)updateActiveURL:(const GURL&)url {
#if defined(OS_IOS)
// Handoff is only available on iOS 8+.
DCHECK(base::ios::IsRunningOnIOS8OrLater());
#endif
#if defined(OS_MACOSX) && !defined(OS_IOS)
// Handoff is only available on OSX 10.10+.
DCHECK(base::mac::IsOSYosemiteOrLater());
#endif
_activeURL = url;
[self updateUserActivity];
}
- (BOOL)shouldUseActiveURL {
return _activeURL.SchemeIsHTTPOrHTTPS();
}
- (void)updateUserActivity {
// Clear the user activity.
if (![self shouldUseActiveURL]) {
[self.userActivity invalidate];
self.userActivity = nil;
return;
}
// No change to the user activity.
const GURL userActivityURL(net::GURLWithNSURL(self.userActivity.webpageURL));
if (userActivityURL == _activeURL)
return;
// Invalidate the old user activity and make a new one.
[self.userActivity invalidate];
Class aClass = NSClassFromString(@"NSUserActivity");
NSUserActivity* userActivity = [[aClass performSelector:@selector(alloc)]
performSelector:@selector(initWithActivityType:)
withObject:handoff::kChromeHandoffActivityType];
self.userActivity = base::scoped_nsobject<NSUserActivity>(userActivity);
self.userActivity.webpageURL = net::NSURLWithGURL(_activeURL);
NSString* origin = handoff::StringFromOrigin(_origin);
DCHECK(origin);
self.userActivity.userInfo = @{ handoff::kOriginKey : origin };
[self.userActivity becomeCurrent];
}
@end
|
