1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//content/browser/browser.gni")
import("//build/config/ui.gni")
# See //content/BUILD.gn for how this works.
group("browser") {
if (is_component_build) {
public_deps = [
"//content",
]
} else {
public_deps = [
":browser_sources",
]
}
}
source_set("browser_sources") {
visibility = [ "//content/*" ]
sources = rebase_path(content_browser_gypi_values.public_browser_sources,
".",
"//content")
configs += [
"//build/config:precompiled_headers",
"//content:content_implementation",
]
public_deps = [
"//content/public/common:mojo_bindings",
"//mojo/public/cpp/bindings",
"//mojo/public/cpp/system",
# We expose skia headers in the public API.
"//skia",
]
deps = [
"//cc",
"//content/browser",
"//content/public/common:common_sources",
"//gpu",
"//media",
"//net",
"//ppapi/c",
"//storage/browser",
"//ui/accessibility",
"//ui/base",
"//ui/events",
"//ui/gl",
"//ui/surface",
]
allow_circular_includes_from = [
# This target is a pair with content/browser. They always go together and
# include headers from each other.
"//content/browser",
]
if (is_android) {
deps += [ "//ui/android" ]
}
if (use_aura) {
sources -= [ "context_factory.h" ]
deps += [ "//ui/aura" ]
}
}
|
