blob: 1c4a03776d08c5bd638b71c37a36e92162377125 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
// Copyright 2014 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#import "ios/chrome/browser/memory/memory_debugger_manager.h"
#include "base/ios/weak_nsobject.h"
#import "base/mac/bind_objc_block.h"
#include "base/mac/scoped_nsobject.h"
#include "components/prefs/pref_member.h"
#include "components/prefs/pref_registry_simple.h"
#include "components/prefs/pref_service.h"
#import "ios/chrome/browser/memory/memory_debugger.h"
#import "ios/chrome/browser/pref_names.h"
@implementation MemoryDebuggerManager {
UIView* debuggerParentView_; // weak
base::scoped_nsobject<MemoryDebugger> memoryDebugger_;
BooleanPrefMember showMemoryDebugger_;
}
- (instancetype)initWithView:(UIView*)debuggerParentView
prefs:(PrefService*)prefs {
if (self = [super init]) {
debuggerParentView_ = debuggerParentView;
// Set up the callback for when the pref to show/hide the debugger changes.
base::WeakNSObject<MemoryDebuggerManager> weakSelf(self);
base::Closure callback = base::BindBlock(^{
base::scoped_nsobject<MemoryDebuggerManager> strongSelf(
[weakSelf retain]);
if (strongSelf) {
[self onShowMemoryDebuggingToolsChange];
}
});
showMemoryDebugger_.Init(prefs::kShowMemoryDebuggingTools, prefs, callback);
// Invoke the pref change callback once to show the debugger on start up,
// if necessary.
[self onShowMemoryDebuggingToolsChange];
}
return self;
}
- (void)dealloc {
[self tearDownDebugger];
[super dealloc];
}
#pragma mark - Pref-handling methods
// Registers local state prefs.
+ (void)registerLocalState:(PrefRegistrySimple*)registry {
registry->RegisterBooleanPref(prefs::kShowMemoryDebuggingTools, false);
}
// Shows or hides the debugger when the pref changes.
- (void)onShowMemoryDebuggingToolsChange {
if (showMemoryDebugger_.GetValue()) {
memoryDebugger_.reset([[MemoryDebugger alloc] init]);
[debuggerParentView_ addSubview:memoryDebugger_];
} else {
[self tearDownDebugger];
}
}
// Tears down the debugger so it can be deallocated.
- (void)tearDownDebugger {
[memoryDebugger_ invalidateTimers];
[memoryDebugger_ removeFromSuperview];
memoryDebugger_.reset();
}
@end
|
