1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
|
// Copyright 2013 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#include "ios/chrome/browser/translate/after_translate_infobar_controller.h"
#include "base/strings/sys_string_conversions.h"
#include "base/strings/utf_string_conversions.h"
#include "components/strings/grit/components_strings.h"
#include "components/translate/core/browser/translate_infobar_delegate.h"
#include "ios/chrome/browser/translate/translate_infobar_tags.h"
#include "ios/public/provider/chrome/browser/chrome_browser_provider.h"
#import "ios/public/provider/chrome/browser/ui/infobar_view_delegate.h"
#import "ios/public/provider/chrome/browser/ui/infobar_view_protocol.h"
#include "ui/base/l10n/l10n_util.h"
#include "ui/gfx/image/image.h"
@interface AfterTranslateInfoBarController () {
translate::TranslateInfoBarDelegate* _translateInfoBarDelegate; // weak
}
// Action for any of the user defined buttons.
- (void)infoBarButtonDidPress:(id)sender;
@end
@implementation AfterTranslateInfoBarController
#pragma mark -
#pragma mark InfoBarControllerProtocol
- (base::scoped_nsobject<UIView<InfoBarViewProtocol>>)
viewForDelegate:(infobars::InfoBarDelegate*)delegate
frame:(CGRect)frame {
base::scoped_nsobject<UIView<InfoBarViewProtocol>> infoBarView;
_translateInfoBarDelegate = delegate->AsTranslateInfoBarDelegate();
DCHECK(_translateInfoBarDelegate);
infoBarView.reset(
ios::GetChromeBrowserProvider()->CreateInfoBarView(frame, self.delegate));
// Icon
gfx::Image icon = _translateInfoBarDelegate->GetIcon();
if (!icon.IsEmpty())
[infoBarView addLeftIcon:icon.ToUIImage()];
// Main text.
const bool autodeterminedSourceLanguage =
_translateInfoBarDelegate->original_language_code() ==
translate::kUnknownLanguageCode;
bool swappedLanguageButtons;
std::vector<base::string16> strings;
translate::TranslateInfoBarDelegate::GetAfterTranslateStrings(
&strings, &swappedLanguageButtons, autodeterminedSourceLanguage);
DCHECK_EQ(autodeterminedSourceLanguage ? 2U : 3U, strings.size());
NSString* label1 = base::SysUTF16ToNSString(strings[0]);
NSString* label2 = base::SysUTF16ToNSString(strings[1]);
NSString* label3 = autodeterminedSourceLanguage
? @""
: base::SysUTF16ToNSString(strings[2]);
base::string16 stdOriginal =
_translateInfoBarDelegate->original_language_name();
NSString* original = base::SysUTF16ToNSString(stdOriginal);
NSString* target = base::SysUTF16ToNSString(
_translateInfoBarDelegate->target_language_name());
base::scoped_nsobject<NSString> label(
[[NSString alloc] initWithFormat:@"%@ %@ %@%@ %@.", label1, original,
label2, label3, target]);
[infoBarView addLabel:label];
// Close button.
[infoBarView addCloseButtonWithTag:TranslateInfoBarIOSTag::CLOSE
target:self
action:@selector(infoBarButtonDidPress:)];
// Other buttons.
NSString* buttonRevert = l10n_util::GetNSString(IDS_TRANSLATE_INFOBAR_REVERT);
NSString* buttonOptions = l10n_util::GetNSString(IDS_DONE);
[infoBarView addButton1:buttonOptions
tag1:TranslateInfoBarIOSTag::AFTER_DONE
button2:buttonRevert
tag2:TranslateInfoBarIOSTag::AFTER_REVERT
target:self
action:@selector(infoBarButtonDidPress:)];
// Always translate switch.
if (_translateInfoBarDelegate->ShouldShowAlwaysTranslateShortcut()) {
base::string16 alwaysTranslate = l10n_util::GetStringFUTF16(
IDS_TRANSLATE_INFOBAR_ALWAYS_TRANSLATE, stdOriginal);
const BOOL switchValue = _translateInfoBarDelegate->ShouldAlwaysTranslate();
[infoBarView
addSwitchWithLabel:base::SysUTF16ToNSString(alwaysTranslate)
isOn:switchValue
tag:TranslateInfoBarIOSTag::ALWAYS_TRANSLATE_SWITCH
target:self
action:@selector(infoBarSwitchDidPress:)];
}
return infoBarView;
}
#pragma mark - Handling of User Events
- (void)infoBarButtonDidPress:(id)sender {
// This press might have occurred after the user has already pressed a button,
// in which case the view has been detached from the delegate and this press
// should be ignored.
if (!self.delegate) {
return;
}
if ([sender isKindOfClass:[UIButton class]]) {
NSUInteger buttonId = static_cast<UIButton*>(sender).tag;
if (buttonId == TranslateInfoBarIOSTag::CLOSE) {
self.delegate->InfoBarDidCancel();
} else {
DCHECK(buttonId == TranslateInfoBarIOSTag::AFTER_REVERT ||
buttonId == TranslateInfoBarIOSTag::AFTER_DONE);
self.delegate->InfoBarButtonDidPress(buttonId);
}
}
}
- (void)infoBarSwitchDidPress:(id)sender {
DCHECK_EQ(TranslateInfoBarIOSTag::ALWAYS_TRANSLATE_SWITCH, [sender tag]);
DCHECK([sender respondsToSelector:@selector(isOn)]);
if (_translateInfoBarDelegate->ShouldAlwaysTranslate() != [sender isOn])
_translateInfoBarDelegate->ToggleAlwaysTranslate();
}
@end
|
