1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
|
# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.
import("//testing/test.gni")
# The list of files is kept in the .gypi.
gypi_values = exec_script("//build/gypi_to_gn.py",
[ rebase_path("wtf.gypi") ],
"scope",
[ "wtf.gypi" ])
visibility = [ "//third_party/WebKit/*" ]
config("wtf_config") {
if (is_win) {
defines = [
"__STD_C",
"_CRT_SECURE_NO_DEPRECATE",
"_SCL_SECURE_NO_DEPRECATE",
]
include_dirs = [ "os-win32" ]
cflags = [
# Don't complain about calling specific versions of templatized
# functions (e.g. in RefPtrHashMap.h).
"/wd4344",
# dtoa, icu, etc. like doing assignment within conditional.
"/wd4706",
]
if (is_component_build) {
# Chromium windows multi-dll build enables C++ exceptions and this causes
# wtf to generate 4291 warning due to operator new/delete
# implementations. Disable the warning for chromium windows multi-dll
# build.
cflags += [ "/wd4291" ]
}
}
}
component("wtf") {
sources = gypi_values.wtf_files
configs += [
"//third_party/WebKit/Source:config",
"//third_party/WebKit/Source:non_test_config",
]
defines = [ "WTF_IMPLEMENTATION=1" ]
public_configs = [
":wtf_config",
# TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
"//build/config/compiler:no_size_t_to_int_warning",
"//third_party/WebKit/Source:features",
]
public_deps = [
"//base",
"//third_party/icu",
]
if (is_win) {
sources -= [ "ThreadingPthreads.cpp" ]
cflags = [ "/wd4068" ] # Unknown pragma.
} else {
# Non-Windows.
sources -= [
"ThreadSpecificWin.cpp",
"ThreadingWin.cpp",
]
}
if (is_android) {
libs = [ "log" ]
}
if (is_linux) {
libs = [ "dl" ]
}
if (is_mac) {
libs = [
"CoreFoundation.framework",
"Foundation.framework",
]
} else {
sources -= [
"text/AtomicStringCF.cpp",
"text/StringImplCF.cpp",
]
}
}
# TODO(GYP): Delete this after we've converted everything to GN.
# The _run targets exist only for compatibility w/ GYP.
group("wtf_unittests_run") {
testonly = true
deps = [
":wtf_unittests",
]
}
test("wtf_unittests") {
visibility = [] # Allow re-assignment of list.
visibility = [ "*" ]
sources = gypi_values.wtf_unittest_files
sources += [ "testing/RunAllTests.cpp" ]
# TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
if (is_win) {
cflags = [ "/wd4068" ] # Unknown pragma.
}
configs += [ "//third_party/WebKit/Source:config" ]
deps = [
":test_support",
":wtf",
"//base",
"//base/test:test_support",
"//testing/gmock",
"//testing/gtest",
]
}
component("test_support") {
output_name = "wtf_test_support"
sources = gypi_values.wtf_unittest_helper_files
defines = [ "WTF_UNITTEST_HELPERS_IMPLEMENTATION=1" ]
configs += [
":wtf_config",
# TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
"//build/config/compiler:no_size_t_to_int_warning",
"//third_party/WebKit/Source:config",
"//third_party/WebKit/Source:non_test_config",
]
deps = [
":wtf",
]
}
|
