blob: 548b83a5dd68569a05d22510c25c12ccd1139633 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
// Copyright (c) 2010 The Chromium Authors. All rights reserved.
// Use of this source code is governed by a BSD-style license that can be
// found in the LICENSE file.
#import <Cocoa/Cocoa.h>
#import <QuartzCore/QuartzCore.h>
#include "base/logging.h"
#include "base/mac_util.h"
#include "base/scoped_nsobject.h"
#import "chrome/browser/ui/cocoa/confirm_quit_panel_controller.h"
@interface ConfirmQuitPanelController (Private)
- (id)initInternal;
- (void)animateFadeOut;
@end
ConfirmQuitPanelController* g_confirmQuitPanelController = nil;
@implementation ConfirmQuitPanelController
+ (ConfirmQuitPanelController*)sharedController {
if (!g_confirmQuitPanelController) {
g_confirmQuitPanelController =
[[ConfirmQuitPanelController alloc] initInternal];
}
return g_confirmQuitPanelController;
}
- (id)initInternal {
NSString* nibPath =
[mac_util::MainAppBundle() pathForResource:@"ConfirmQuitPanel"
ofType:@"nib"];
if ((self = [super initWithWindowNibPath:nibPath owner:self])) {
}
return self;
}
- (void)awakeFromNib {
DCHECK([self window]);
DCHECK_EQ(self, [[self window] delegate]);
}
- (void)windowWillClose:(NSNotification*)notif {
// Release all animations because CAAnimation retains its delegate (self),
// which will cause a retain cycle. Break it!
[[self window] setAnimations:[NSDictionary dictionary]];
g_confirmQuitPanelController = nil;
[self autorelease];
}
- (void)showWindow:(id)sender {
// If a panel that is fading out is going to be reused here, make sure it
// does not get released when the animation finishes.
scoped_nsobject<ConfirmQuitPanelController> stayAlive([self retain]);
[[self window] setAnimations:[NSDictionary dictionary]];
[[self window] center];
[[self window] setAlphaValue:1.0];
[super showWindow:sender];
}
- (void)dismissPanel {
[self performSelector:@selector(animateFadeOut)
withObject:nil
afterDelay:1.0];
}
- (void)animateFadeOut {
NSWindow* window = [self window];
scoped_nsobject<CAAnimation> animation(
[[window animationForKey:@"alphaValue"] copy]);
[animation setDelegate:self];
[animation setDuration:0.2];
NSMutableDictionary* dictionary =
[NSMutableDictionary dictionaryWithDictionary:[window animations]];
[dictionary setObject:animation forKey:@"alphaValue"];
[window setAnimations:dictionary];
[[window animator] setAlphaValue:0.0];
}
- (void)animationDidStop:(CAAnimation*)theAnimation finished:(BOOL)finished {
[self close];
}
@end
|
